configure.ac 68 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586878889909192939495969798991001011021031041051061071081091101111121131141151161171181191201211221231241251261271281291301311321331341351361371381391401411421431441451461471481491501511521531541551561571581591601611621631641651661671681691701711721731741751761771781791801811821831841851861871881891901911921931941951961971981992002012022032042052062072082092102112122132142152162172182192202212222232242252262272282292302312322332342352362372382392402412422432442452462472482492502512522532542552562572582592602612622632642652662672682692702712722732742752762772782792802812822832842852862872882892902912922932942952962972982993003013023033043053063073083093103113123133143153163173183193203213223233243253263273283293303313323333343353363373383393403413423433443453463473483493503513523533543553563573583593603613623633643653663673683693703713723733743753763773783793803813823833843853863873883893903913923933943953963973983994004014024034044054064074084094104114124134144154164174184194204214224234244254264274284294304314324334344354364374384394404414424434444454464474484494504514524534544554564574584594604614624634644654664674684694704714724734744754764774784794804814824834844854864874884894904914924934944954964974984995005015025035045055065075085095105115125135145155165175185195205215225235245255265275285295305315325335345355365375385395405415425435445455465475485495505515525535545555565575585595605615625635645655665675685695705715725735745755765775785795805815825835845855865875885895905915925935945955965975985996006016026036046056066076086096106116126136146156166176186196206216226236246256266276286296306316326336346356366376386396406416426436446456466476486496506516526536546556566576586596606616626636646656666676686696706716726736746756766776786796806816826836846856866876886896906916926936946956966976986997007017027037047057067077087097107117127137147157167177187197207217227237247257267277287297307317327337347357367377387397407417427437447457467477487497507517527537547557567577587597607617627637647657667677687697707717727737747757767777787797807817827837847857867877887897907917927937947957967977987998008018028038048058068078088098108118128138148158168178188198208218228238248258268278288298308318328338348358368378388398408418428438448458468478488498508518528538548558568578588598608618628638648658668678688698708718728738748758768778788798808818828838848858868878888898908918928938948958968978988999009019029039049059069079089099109119129139149159169179189199209219229239249259269279289299309319329339349359369379389399409419429439449459469479489499509519529539549559569579589599609619629639649659669679689699709719729739749759769779789799809819829839849859869879889899909919929939949959969979989991000100110021003100410051006100710081009101010111012101310141015101610171018101910201021102210231024102510261027102810291030103110321033103410351036103710381039104010411042104310441045104610471048104910501051105210531054105510561057105810591060106110621063106410651066106710681069107010711072107310741075107610771078107910801081108210831084108510861087108810891090109110921093109410951096109710981099110011011102110311041105110611071108110911101111111211131114111511161117111811191120112111221123112411251126112711281129113011311132113311341135113611371138113911401141114211431144114511461147114811491150115111521153115411551156115711581159116011611162116311641165116611671168116911701171117211731174117511761177117811791180118111821183118411851186118711881189119011911192119311941195119611971198119912001201120212031204120512061207120812091210121112121213121412151216121712181219122012211222122312241225122612271228122912301231123212331234123512361237123812391240124112421243124412451246124712481249125012511252125312541255125612571258125912601261126212631264126512661267126812691270127112721273127412751276127712781279128012811282128312841285128612871288128912901291129212931294129512961297129812991300130113021303130413051306130713081309131013111312131313141315131613171318131913201321132213231324132513261327132813291330133113321333133413351336133713381339134013411342134313441345134613471348134913501351135213531354135513561357135813591360136113621363136413651366136713681369137013711372137313741375137613771378137913801381138213831384138513861387138813891390139113921393139413951396139713981399140014011402140314041405140614071408140914101411141214131414141514161417141814191420142114221423142414251426142714281429143014311432143314341435143614371438143914401441144214431444144514461447144814491450145114521453145414551456145714581459146014611462146314641465146614671468146914701471147214731474147514761477147814791480148114821483148414851486148714881489149014911492149314941495149614971498149915001501150215031504150515061507150815091510151115121513151415151516151715181519152015211522152315241525152615271528152915301531153215331534153515361537153815391540154115421543154415451546154715481549155015511552155315541555155615571558155915601561156215631564156515661567156815691570157115721573157415751576157715781579158015811582158315841585158615871588158915901591159215931594159515961597159815991600160116021603160416051606160716081609161016111612161316141615161616171618161916201621162216231624162516261627162816291630163116321633163416351636163716381639164016411642164316441645164616471648164916501651165216531654165516561657165816591660166116621663166416651666166716681669167016711672167316741675167616771678167916801681168216831684168516861687168816891690169116921693169416951696169716981699170017011702170317041705170617071708170917101711171217131714171517161717171817191720172117221723172417251726172717281729173017311732173317341735173617371738173917401741174217431744174517461747174817491750175117521753175417551756175717581759176017611762176317641765176617671768176917701771177217731774177517761777177817791780178117821783178417851786178717881789179017911792179317941795179617971798179918001801180218031804180518061807180818091810181118121813181418151816181718181819182018211822182318241825182618271828182918301831183218331834183518361837183818391840184118421843184418451846184718481849185018511852185318541855185618571858185918601861186218631864186518661867186818691870187118721873187418751876187718781879188018811882188318841885188618871888188918901891189218931894189518961897189818991900190119021903190419051906190719081909191019111912191319141915191619171918191919201921192219231924192519261927192819291930193119321933193419351936
  1. # StarPU --- Runtime system for heterogeneous multicore architectures.
  2. #
  3. # Copyright (C) 2009-2013 Université de Bordeaux 1
  4. # Copyright (C) 2010, 2011, 2012 Centre National de la Recherche Scientifique
  5. # Copyright (C) 2011 Télécom-SudParis
  6. # Copyright (C) 2011, 2012 Institut National de Recherche en Informatique et Automatique
  7. #
  8. # StarPU is free software; you can redistribute it and/or modify
  9. # it under the terms of the GNU Lesser General Public License as published by
  10. # the Free Software Foundation; either version 2.1 of the License, or (at
  11. # your option) any later version.
  12. #
  13. # StarPU is distributed in the hope that it will be useful, but
  14. # WITHOUT ANY WARRANTY; without even the implied warranty of
  15. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  16. #
  17. # See the GNU Lesser General Public License in COPYING.LGPL for more details.
  18. AC_INIT([StarPU], [1.1.0], [starpu-devel@lists.gforge.inria.fr],
  19. [starpu], [http://runtime.bordeaux.inria.fr/StarPU/])
  20. AC_CONFIG_SRCDIR(include/starpu.h)
  21. AC_CONFIG_AUX_DIR([build-aux])
  22. dnl Versioning.
  23. STARPU_MAJOR_VERSION="`echo $PACKAGE_VERSION | cut -d . -f 1`"
  24. STARPU_MINOR_VERSION="`echo $PACKAGE_VERSION | cut -d . -f 2`"
  25. AC_SUBST([STARPU_MAJOR_VERSION])
  26. AC_SUBST([STARPU_MINOR_VERSION])
  27. AC_SUBST([STARPU_EFFECTIVE_VERSION])
  28. AC_DEFINE_UNQUOTED([STARPU_MAJOR_VERSION], [$STARPU_MAJOR_VERSION], [Major version number of StarPU.])
  29. AC_DEFINE_UNQUOTED([STARPU_MINOR_VERSION], [$STARPU_MINOR_VERSION], [Minor version number of StarPU.])
  30. . "$srcdir/STARPU-VERSION"
  31. AC_SUBST([LIBSTARPU_INTERFACE_CURRENT])
  32. AC_SUBST([LIBSTARPU_INTERFACE_REVISION])
  33. AC_SUBST([LIBSTARPU_INTERFACE_AGE])
  34. AC_SUBST([LIBSTARPUMPI_INTERFACE_CURRENT])
  35. AC_SUBST([LIBSTARPUMPI_INTERFACE_REVISION])
  36. AC_SUBST([LIBSTARPUMPI_INTERFACE_AGE])
  37. AC_SUBST([LIBSTARPUFFT_INTERFACE_CURRENT])
  38. AC_SUBST([LIBSTARPUFFT_INTERFACE_REVISION])
  39. AC_SUBST([LIBSTARPUFFT_INTERFACE_AGE])
  40. AC_SUBST([LIBSOCL_INTERFACE_CURRENT])
  41. AC_SUBST([LIBSOCL_INTERFACE_REVISION])
  42. AC_SUBST([LIBSOCL_INTERFACE_AGE])
  43. AC_CANONICAL_SYSTEM
  44. dnl Automake 1.11 introduced `silent-rules' and `color-tests'. Use them
  45. dnl when they're available.
  46. m4_ifdef([AM_SILENT_RULES],
  47. [AM_INIT_AUTOMAKE([1.11 -Wall -Werror foreign silent-rules color-tests parallel-tests])],
  48. [AM_INIT_AUTOMAKE([1.10 -Wall -Werror foreign])])
  49. m4_ifdef([AM_SILENT_RULES],
  50. [AM_SILENT_RULES(yes)])
  51. AC_PREREQ(2.60)
  52. m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  53. AC_PROG_CC
  54. AM_PROG_CC_C_O
  55. AC_PROG_CXX
  56. AC_PROG_CPP
  57. AC_PROG_SED
  58. AC_PROG_LN_S
  59. AC_PROG_F77
  60. LT_PREREQ([2.2])
  61. LT_INIT([win32-dll])
  62. AC_PROG_INSTALL
  63. AC_PROG_MKDIR_P
  64. AC_PROG_LN_S
  65. AC_HEADER_STDC
  66. AC_C_RESTRICT
  67. AC_PATH_PROGS([STARPU_MS_LIB], [lib])
  68. AC_ARG_VAR([STARPU_MS_LIB], [Path to Microsoft's Visual Studio `lib' tool])
  69. AM_CONDITIONAL([STARPU_HAVE_MS_LIB], [test "x$STARPU_MS_LIB" != "x"])
  70. case "$target" in
  71. *-*-mingw*|*-*-cygwin*)
  72. starpu_windows=yes
  73. libext=a
  74. AC_DEFINE(STARPU_HAVE_WINDOWS, [], [Define this on windows.])
  75. ;;
  76. esac
  77. AM_CONDITIONAL([STARPU_HAVE_WINDOWS], [test "x$starpu_windows" = "xyes"])
  78. # on Darwin, GCC targets i386 by default, so we don't have atomic ops
  79. AC_CHECK_SIZEOF([void *])
  80. SIZEOF_VOID_P=$ac_cv_sizeof_void_p
  81. case $SIZEOF_VOID_P in
  82. 4)
  83. case "$target" in
  84. i386-*darwin*) CFLAGS+=" -march=i686 " ;;
  85. esac
  86. STARPU_MS_LIB_ARCH=X86
  87. ;;
  88. 8)
  89. STARPU_MS_LIB_ARCH=X64
  90. ;;
  91. esac
  92. AC_SUBST(STARPU_MS_LIB_ARCH)
  93. # This will be useful for program which use CUDA (and .cubin files) which need
  94. # some path to the CUDA code at runtime.
  95. AC_DEFINE_UNQUOTED(STARPU_BUILD_DIR, "$PWD", [location of StarPU build directory])
  96. AC_SUBST(STARPU_BUILD_DIR, $PWD)
  97. case "${srcdir}" in
  98. /*) AC_DEFINE_UNQUOTED(STARPU_SRC_DIR, "$(eval echo ${srcdir})", [location of StarPU sources])
  99. AC_SUBST(STARPU_SRC_DIR, "$(eval echo ${srcdir})") ;;
  100. *) AC_DEFINE_UNQUOTED(STARPU_SRC_DIR, "$(eval echo $PWD/${srcdir})", [location of StarPU sources])
  101. AC_SUBST(STARPU_SRC_DIR, "$(eval echo $PWD/${srcdir})") ;;
  102. esac
  103. case "$target" in
  104. *-*-mingw*|*-*-cygwin*)
  105. AC_ARG_ENABLE(native-winthreads, [AS_HELP_STRING([--enable-native-winthreads],
  106. [Use native windows threads instead of pthread])],
  107. enable_native_winthreads=$enableval, enable_native_winthreads=no)
  108. ;;
  109. esac
  110. if test x"$enable_native_winthreads" = xyes
  111. then
  112. CPPFLAGS+=" -I$STARPU_SRC_DIR/include/pthread_win32 "
  113. else
  114. AC_CHECK_LIB([pthread], [pthread_create])
  115. fi
  116. AC_COMPILE_IFELSE(
  117. [AC_LANG_PROGRAM([[
  118. #include <pthread.h>
  119. ]], [[ pthread_t t; pthread_create(&t, NULL, NULL, NULL); ]])],,
  120. AC_MSG_ERROR([pthread_create unavailable]))
  121. AC_SEARCH_LIBS([sqrt],[m],,AC_MSG_ERROR([math library unavailable]))
  122. AC_HAVE_LIBRARY([ws2_32])
  123. AC_CHECK_FUNCS([sysconf])
  124. AC_CHECK_FUNC([pthread_spin_lock], have_pthread_spin_lock=yes, have_pthread_spin_lock=no)
  125. if test x$have_pthread_spin_lock = xyes; then
  126. AC_DEFINE(HAVE_PTHREAD_SPIN_LOCK,[],[pthread_spin_lock is available])
  127. fi
  128. # yes, that's non portable, but it's still better than sched_setaffinity
  129. AC_CHECK_FUNCS(pthread_setaffinity_np)
  130. # There is no posix_memalign on Mac OS X, only memalign
  131. AC_CHECK_FUNCS([posix_memalign], [AC_DEFINE([STARPU_HAVE_POSIX_MEMALIGN], [1], [Define to 1 if you have the `posix_memalign' function.])])
  132. AC_CHECK_FUNCS([memalign], [AC_DEFINE([STARPU_HAVE_MEMALIGN], [1], [Define to 1 if you have the `memalign' function.])])
  133. # Some systems don't have drand48
  134. AC_CHECK_FUNC([drand48], have_drand48=yes, have_drand48=no)
  135. AC_CHECK_FUNC([erand48_r], have_erand48_r=yes, have_erand48_r=no)
  136. # Maybe the user still does not want to use the provided drand48
  137. AC_ARG_ENABLE(default-drand48, [AS_HELP_STRING([--disable-default-drand48],
  138. [Do not use the default version of drand48])],
  139. enable_default_drand48=$enableval, enable_default_drand48=yes)
  140. if test x$have_drand48 = xyes -a x$enable_default_drand48 = xyes ; then
  141. AC_DEFINE([STARPU_USE_DRAND48], [1], [Define to 1 if drandr48 is available and should be used])
  142. fi
  143. if test x$have_erand48_r = xyes ; then
  144. AC_DEFINE([STARPU_USE_ERAND48_R], [1], [Define to 1 if erandr48_r is available])
  145. fi
  146. # Some systems do not define strerror_r
  147. AC_CHECK_FUNC([strerror_r], [AC_DEFINE([STARPU_HAVE_STRERROR_R], [1], [Define to 1 if the function strerro_r is available.])])
  148. # Some systems may not define setenv
  149. AC_CHECK_FUNC([setenv], [AC_DEFINE([STARPU_HAVE_SETENV], [1], [Define to 1 if the function setenv is available.])])
  150. # Some systems do not define unsetenv
  151. AC_CHECK_FUNC([unsetenv], [AC_DEFINE([STARPU_HAVE_UNSETENV], [1], [Define to 1 if the function unsetenv is available.])])
  152. # Some systems do not define nearbyintf...
  153. AC_CHECK_FUNC([nearbyintf], [AC_DEFINE([STARPU_HAVE_NEARBYINTF], [1], [Define to 1 if the function nearbyintf is available.])])
  154. # ... but they may define rintf.
  155. AC_CHECK_FUNC([rintf], [AC_DEFINE([STARPU_HAVE_RINTF], [1], [Define to 1 if the function rintf is available.])])
  156. # Define quick check
  157. AC_ARG_ENABLE(quick-check, [AS_HELP_STRING([--enable-quick-check],
  158. [Lower default values for the testcases run by make check to allow a faster execution])],
  159. enable_quick_check=$enableval, enable_quick_check=no)
  160. if test x$enable_quick_check = xyes; then
  161. AC_DEFINE(STARPU_QUICK_CHECK, [1], [enable quick check])
  162. fi
  163. AM_CONDITIONAL([STARPU_QUICK_CHECK], [test "x$enable_quick_check" = "xyes"])
  164. # Define long check
  165. AC_ARG_ENABLE(long-check, [AS_HELP_STRING([--enable-long-check],
  166. [Enable some exhaustive checks which take a really long time])],
  167. enable_long_check=$enableval, enable_long_check=no)
  168. if test x$enable_long_check = xyes; then
  169. AC_DEFINE(STARPU_LONG_CHECK, [1], [enable long check])
  170. fi
  171. AM_CONDITIONAL([STARPU_LONG_CHECK], [test "x$enable_long_check" = "xyes"])
  172. AC_CHECK_HEADERS([malloc.h], [AC_DEFINE([STARPU_HAVE_MALLOC_H], [1], [Define to 1 if you have the <malloc.h> header file.])])
  173. AC_CHECK_HEADERS([valgrind/valgrind.h], [AC_DEFINE([STARPU_HAVE_VALGRIND_H], [1], [Define to 1 if you have the <valgrind/valgrind.h> header file.])])
  174. # This defines HAVE_SYNC_VAL_COMPARE_AND_SWAP
  175. STARPU_CHECK_SYNC_VAL_COMPARE_AND_SWAP
  176. # This defines HAVE_SYNC_BOOL_COMPARE_AND_SWAP
  177. STARPU_CHECK_SYNC_BOOL_COMPARE_AND_SWAP
  178. # This defines HAVE_SYNC_FETCH_AND_ADD
  179. STARPU_CHECK_SYNC_FETCH_AND_ADD
  180. # This defines HAVE_SYNC_FETCH_AND_OR
  181. STARPU_CHECK_SYNC_FETCH_AND_OR
  182. # This defines HAVE_SYNC_LOCK_TEST_AND_SET
  183. STARPU_CHECK_SYNC_LOCK_TEST_AND_SET
  184. # This defines HAVE_SYNC_SYNCHRONIZE
  185. STARPU_CHECK_SYNC_SYNCHRONIZE
  186. CPPFLAGS="${CPPFLAGS} -D_GNU_SOURCE "
  187. STARPU_SEARCH_LIBS([LIBNUMA],[set_mempolicy],[numa],[enable_libnuma=yes],[enable_libnuma=no])
  188. AC_MSG_CHECKING(whether libnuma is available)
  189. AC_MSG_RESULT($enable_libnuma)
  190. if test x$enable_libnuma = xyes; then
  191. AC_DEFINE(STARPU_HAVE_LIBNUMA,[],[libnuma is available])
  192. fi
  193. ###############################################################################
  194. # #
  195. # SCHED_CTX settings #
  196. # #
  197. ###############################################################################
  198. AC_MSG_CHECKING(maximum number of sched_ctxs)
  199. AC_ARG_ENABLE(max_sched_ctxs, [AS_HELP_STRING([--enable-max-sched-ctxs=<number>],
  200. [maximum number of sched_ctxs])],
  201. max_sched_ctxs=$enableval, max_sched_ctxs=10)
  202. AC_MSG_RESULT($max_sched_ctxs)
  203. AC_DEFINE_UNQUOTED(STARPU_NMAX_SCHED_CTXS, [$max_sched_ctxs], [Maximum number of sched_ctxs supported])
  204. AC_ARG_ENABLE([sched_ctx_hypervisor],
  205. [AS_HELP_STRING([--enable-sched-ctx-hypervisor],
  206. [enable resizing contexts (experimental)])],
  207. [enable_sched_ctx_hypervisor="yes"],
  208. [enable_sched_ctx_hypervisor="no"])
  209. #for pkgconfig
  210. AC_SUBST(STARPU_SCHED_CTX_HYPERVISOR)
  211. if test "x$enable_sched_ctx_hypervisor" = "xyes"; then
  212. AC_DEFINE(STARPU_USE_SCHED_CTX_HYPERVISOR, [1], [enable sched_ctx_hypervisor lib])
  213. # PKG_CHECK_MODULES([SCHED_CTX_HYPERVISOR], [libsched_ctx_hypervisor], [], build_sched_ctx_hypervisor="yes")
  214. STARPU_SCHED_CTX_HYPERVISOR="-lsched_ctx_hypervisor"
  215. build_sched_ctx_hypervisor="yes"
  216. else
  217. build_sched_ctx_hypervisor="no"
  218. fi
  219. AM_CONDITIONAL([STARPU_BUILD_SCHED_CTX_HYPERVISOR], [test "x$build_sched_ctx_hypervisor" = "xyes"])
  220. AM_CONDITIONAL([STARPU_USE_SCHED_CTX_HYPERVISOR], [test "x$build_sched_ctx_hypervisor" = "xyes"])
  221. ###############################################################################
  222. # #
  223. # CPUs settings #
  224. # #
  225. ###############################################################################
  226. AC_MSG_CHECKING(maximum number of CPUs)
  227. AC_ARG_ENABLE(maxcpus, [AS_HELP_STRING([--enable-maxcpus=<number>],
  228. [maximum number of CPUs])],
  229. maxcpus=$enableval, maxcpus=64)
  230. AC_MSG_RESULT($maxcpus)
  231. AC_DEFINE_UNQUOTED(STARPU_MAXCPUS, [$maxcpus], [Maximum number of CPUs supported])
  232. AC_MSG_CHECKING(whether CPUs should be used)
  233. AC_ARG_ENABLE(cpu, [AS_HELP_STRING([--disable-cpu],
  234. [do not use the CPU(s)])],
  235. enable_cpu=$enableval, enable_cpu=yes)
  236. AC_MSG_RESULT($enable_cpu)
  237. AC_SUBST(STARPU_USE_CPU, $enable_cpu)
  238. AM_CONDITIONAL(STARPU_USE_CPU, test x$enable_cpu = xyes)
  239. if test x$enable_cpu = xyes; then
  240. AC_DEFINE(STARPU_USE_CPU, [1], [CPU driver is activated])
  241. fi
  242. # How many parallel worker can we support ?
  243. nmaxcombinedworkers=`expr 2 \* $maxcpus`
  244. AC_DEFINE_UNQUOTED(STARPU_NMAX_COMBINEDWORKERS,
  245. [$nmaxcombinedworkers], [Maximum number of worker combinations])
  246. ###############################################################################
  247. # #
  248. # CUDA settings #
  249. # #
  250. ###############################################################################
  251. AC_MSG_CHECKING(maximum number of CUDA devices)
  252. AC_ARG_ENABLE(maxcudadev, [AS_HELP_STRING([--enable-maxcudadev=<number>],
  253. [maximum number of CUDA devices])],
  254. nmaxcudadev=$enableval, nmaxcudadev=4)
  255. AC_MSG_RESULT($nmaxcudadev)
  256. AC_DEFINE_UNQUOTED(STARPU_MAXCUDADEVS, [$nmaxcudadev],
  257. [maximum number of CUDA devices])
  258. AC_ARG_ENABLE(cuda, [AS_HELP_STRING([--disable-cuda],
  259. [do not use CUDA device(s)])],, [enable_cuda=maybe])
  260. #AC_MSG_CHECKING(whether CUDA is available)
  261. AC_ARG_WITH(cuda-dir,
  262. [AS_HELP_STRING([--with-cuda-dir=<path>],
  263. [specify CUDA installation directory])],
  264. [
  265. cuda_dir="$withval"
  266. # in case this was not explicit yet
  267. enable_cuda=yes
  268. ], cuda_dir=no)
  269. AC_ARG_WITH(cuda-include-dir,
  270. [AS_HELP_STRING([--with-cuda-include-dir=<path>],
  271. [specify where CUDA headers are installed])],
  272. [
  273. cuda_include_dir="$withval"
  274. # in case this was not explicit yet
  275. enable_cuda=yes
  276. ], [cuda_include_dir=no])
  277. AC_ARG_WITH(cuda-lib-dir,
  278. [AS_HELP_STRING([--with-cuda-lib-dir=<path>],
  279. [specify where CUDA libraries are installed])],
  280. [
  281. cuda_lib_dir="$withval"
  282. # in case this was not explicit yet
  283. enable_cuda=yes
  284. ], [cuda_lib_dir=no])
  285. AC_DEFUN([STARPU_CHECK_CUDA_L],
  286. [
  287. __cuda_L=$1
  288. SAVED_LDFLAGS="${LDFLAGS}"
  289. STARPU_CUDA_LDFLAGS="${__cuda_L}"
  290. AC_MSG_CHECKING(whether CUDA is available with: $__cuda_L)
  291. AC_MSG_RESULT()
  292. LDFLAGS="${SAVED_LDFLAGS} ${__cuda_L}"
  293. AC_HAVE_LIBRARY([cuda],[have_valid_cuda=yes],[have_valid_cuda=no])
  294. unset ac_cv_lib_cuda_main
  295. if test "$have_valid_cuda" = "yes" ; then
  296. AC_HAVE_LIBRARY([cudart],[have_valid_cuda=yes],[have_valid_cuda=no])
  297. unset ac_cv_lib_cudart_main
  298. if test "$have_valid_cuda" = yes ; then
  299. STARPU_CUDA_LDFLAGS="$STARPU_CUDA_LDFLAGS -lcudart"
  300. LDFLAGS="${SAVED_LDFLAGS} ${STARPU_CUDA_LDFLAGS}"
  301. # we also check that CUBLAS is available
  302. AC_HAVE_LIBRARY([cublas],[have_valid_cuda=yes],[have_valid_cuda=no])
  303. unset ac_cv_lib_cublas_main
  304. if test "$have_valid_cuda" = "yes" ; then
  305. STARPU_CUDA_LDFLAGS="$STARPU_CUDA_LDFLAGS -lcublas"
  306. fi
  307. fi
  308. fi
  309. LDFLAGS="${SAVED_LDFLAGS}"
  310. ])
  311. AC_DEFUN([STARPU_CHECK_CUDA],
  312. [
  313. __cuda_dir=$1
  314. __cuda_include_dir=$2
  315. __cuda_lib_dir=$3
  316. if test -z "$__cuda_lib_dir" ; then
  317. __cuda_lib_dir=no
  318. fi
  319. if test -z "$__cuda_include_dir" ; then
  320. __cuda_include_dir=no
  321. fi
  322. if test -z "$__cuda_dir" ; then
  323. __cuda_dir=no
  324. fi
  325. if test "$__cuda_dir" != "no" ; then
  326. AC_MSG_CHECKING(whether CUDA is available in $__cuda_dir, $__cuda_include_dir and $__cuda_lib_dir)
  327. else
  328. AC_MSG_CHECKING(whether CUDA is available)
  329. fi
  330. AC_MSG_RESULT()
  331. if test "$__cuda_include_dir" = "no" -a "$__cuda_dir" != "no" ; then
  332. __cuda_include_dir="$__cuda_dir/include"
  333. fi
  334. SAVED_CPPFLAGS="$CPPFLAGS"
  335. have_valid_cuda=no
  336. if test "$__cuda_include_dir" != "no" ; then
  337. CPPFLAGS="${CPPFLAGS} -I$__cuda_include_dir"
  338. fi
  339. AC_CHECK_HEADER([cuda.h],[have_valid_cuda=yes],[have_valid_cuda=no])
  340. unset ac_cv_header_cuda_h
  341. if test "$have_valid_cuda" = "yes" ; then
  342. if test "$__cuda_lib_dir" != "no" ; then
  343. STARPU_CHECK_CUDA_L("-L${__cuda_lib_dir}")
  344. else
  345. if test "$__cuda_dir" != "no" ; then
  346. for __cuda_libdir in lib64 lib lib/x64 lib/Win32 ; do
  347. STARPU_CHECK_CUDA_L("-L${__cuda_dir}/${__cuda_libdir}")
  348. if test "$have_valid_cuda" = yes ; then
  349. break
  350. fi
  351. done
  352. else
  353. STARPU_CHECK_CUDA_L("")
  354. fi
  355. fi
  356. fi
  357. if test "$have_valid_cuda" = "no" ; then
  358. CPPFLAGS="${SAVED_CPPFLAGS}"
  359. unset STARPU_CUDA_LDFLAGS
  360. else
  361. # nvcc is a wrapper around GCC, and calls it with the -dumpspecs
  362. # option, which is GCC specific. If $CC does not support -dumpspecs, we
  363. # should let nvcc choose another compiler (by default, gcc, if it is
  364. # installed). If gcc is not installed, the build will probably fail.
  365. $CC -dumpspecs >/dev/null 2>&1
  366. if test $? -eq 0 -a x$starpu_windows != xyes; then
  367. NVCCFLAGS="${NVCCFLAGS} -ccbin \${CC}"
  368. fi
  369. if test "$__cuda_include_dir" != "no"; then
  370. STARPU_CUDA_CPPFLAGS="-I$__cuda_include_dir"
  371. NVCCFLAGS="${NVCCFLAGS} -I$__cuda_include_dir"
  372. fi
  373. fi
  374. ])
  375. if test x$enable_cuda = xyes -o x$enable_cuda = xmaybe; then
  376. STARPU_CHECK_CUDA("$cuda_dir", "$cuda_include_dir", "$cuda_lib_dir")
  377. if test "$have_valid_cuda" = "no" ; then
  378. STARPU_CHECK_CUDA("$CUDA_ROOT", "$CUDA_PATH", "$CUDA_INC_PATH", "$CUDA_LIB_PATH")
  379. fi
  380. if test "$have_valid_cuda" = "no" ; then
  381. for f in "/usr/local/cuda" "/c/cuda" "/cygdrive/c/cuda" "/opt/cuda" "$CUDA_ROOT" "$CUDA_PATH" "$CUDA_INC_PATH/.." "$CUDA_INSTALL_PATH" "$CUDA_TOOLKIT"; do
  382. if test -n "$f" ; then
  383. STARPU_CHECK_CUDA("$f", "no", "no")
  384. if test "$have_valid_cuda" = "yes" ; then
  385. break
  386. fi
  387. fi
  388. done
  389. fi
  390. # Check cuda is compatible with the C compiler
  391. AC_MSG_CHECKING(whether CUDA is working)
  392. if test "$have_valid_cuda" = "yes" ; then
  393. SAVED_CPPFLAGS="${CPPFLAGS}"
  394. CPPFLAGS="${CPPFLAGS} ${STARPU_CUDA_CPPFLAGS}"
  395. SAVED_LDFLAGS="${LDFLAGS}"
  396. LDFLAGS="${LDFLAGS} ${STARPU_CUDA_LDFLAGS} -lcuda"
  397. AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
  398. [[#include <cuda.h>]],
  399. [[]]
  400. )],
  401. [
  402. AC_RUN_IFELSE([AC_LANG_PROGRAM(
  403. [[#include <cuda.h>]],
  404. [[]]
  405. )],
  406. [have_valid_cuda="yes"],
  407. [
  408. AC_MSG_RESULT([CUDA found and can be compiled, but compiled application can not be run, is the CUDA path missing in LD_LIBRARY_PATH?])
  409. have_valid_cuda="no"
  410. ])
  411. ],
  412. [
  413. AC_MSG_ERROR([CUDA found, but cuda.h could not be compiled])
  414. have_valid_cuda="no"
  415. ]
  416. )
  417. CPPFLAGS="${SAVED_CPPFLAGS}"
  418. LDFLAGS="${SAVED_LDFLAGS}"
  419. fi
  420. AC_MSG_RESULT($have_valid_cuda)
  421. # in case CUDA was explicitely required, but is not available, this is an error
  422. if test x$enable_cuda = xyes -a x$have_valid_cuda = xno; then
  423. AC_MSG_ERROR([cannot find CUDA])
  424. fi
  425. # now we enable CUDA if and only if a proper setup is available
  426. enable_cuda=$have_valid_cuda
  427. fi
  428. if test x$enable_cuda = xyes; then
  429. if test "$NVCC" = "" ; then
  430. AC_PATH_PROG([NVCC], [nvcc], [not-found],
  431. [$cuda_dir/bin:$PATH:/usr/local/cuda/bin:/usr/bin:/bin])
  432. fi
  433. if test "x$NVCC" = "xnot-found"; then
  434. AC_MSG_WARN(['nvcc' not found, disabling CUDA])
  435. enable_cuda=no
  436. fi
  437. fi
  438. AC_MSG_CHECKING(whether CUDA should be used)
  439. AC_MSG_RESULT($enable_cuda)
  440. AC_SUBST(STARPU_USE_CUDA, $enable_cuda)
  441. AM_CONDITIONAL(STARPU_USE_CUDA, test x$enable_cuda = xyes)
  442. if test x$enable_cuda = xyes; then
  443. AC_DEFINE(STARPU_USE_CUDA, [1], [CUDA support is activated])
  444. # On Darwin, the libstdc++ dependency is not automatically added by nvcc
  445. # case "$target" in
  446. # *-*darwin*) AC_HAVE_LIBRARY([stdc++], []) ;;
  447. # #*-*darwin*) AC_HAVE_LIBRARY([stdc++], [STARPU_CUDA_LDFLAGS="$STARPU_CUDA_LDFLAGS -lstdc++"]) ;;
  448. # esac
  449. STARPU_CUDA_LDFLAGS="$STARPU_CUDA_LDFLAGS -lcuda"
  450. STARPU_CUFFT_LDFLAGS="-lcufft"
  451. if test "$F77" = "gfortran" ; then
  452. STARPU_CUDA_FORTRAN_LDFLAGS="-lgfortran"
  453. AC_SUBST(STARPU_CUDA_FORTRAN_LDFLAGS)
  454. fi
  455. #in case this is a 64bit setup, we tell nvcc to use a -m64 flag
  456. if test x$SIZEOF_VOID_P = x8; then
  457. NVCCFLAGS="${NVCCFLAGS} -m64"
  458. AC_SUBST(NVCCFLAGS)
  459. fi
  460. AC_CHECK_HEADERS([cuda_gl_interop.h])
  461. fi
  462. dnl Hey dude, are you around?
  463. PKG_PROG_PKG_CONFIG
  464. have_magma=no
  465. if test x$enable_cuda = xyes; then
  466. PKG_CHECK_MODULES([MAGMA], [magma], [
  467. AC_DEFINE([STARPU_HAVE_MAGMA], [1], [Define to 1 if you have the MAGMA library.])
  468. AC_SUBST([STARPU_HAVE_MAGMA], [1])
  469. have_magma=yes
  470. ], [:])
  471. fi
  472. AM_CONDITIONAL(STARPU_HAVE_MAGMA, [test x$have_magma = xyes])
  473. AC_MSG_CHECKING(whether MAGMA should be used)
  474. AC_MSG_RESULT($have_magma)
  475. # cufftDoubleComplex may not be available on an old CUDA setup
  476. AC_CHECK_TYPE(cufftDoubleComplex,
  477. [have_cufftdoublecomplex=yes],
  478. [have_cufftdoublecomplex=no], [#include <cufft.h>])
  479. AM_CONDITIONAL(STARPU_HAVE_CUFFTDOUBLECOMPLEX, test x$have_cufftdoublecomplex = xyes)
  480. if test x$have_cufftdoublecomplex = xyes; then
  481. AC_DEFINE(STARPU_HAVE_CUFFTDOUBLECOMPLEX, [1], [cufftDoubleComplex is available])
  482. fi
  483. # The CURAND library is only available since CUDA 3.2
  484. have_curand=$enable_cuda
  485. if test x$enable_cuda = xyes; then
  486. SAVED_LDFLAGS="${LDFLAGS}"
  487. LDFLAGS="${LDFLAGS} ${STARPU_CUDA_LDFLAGS}"
  488. AC_HAVE_LIBRARY([curand],[have_curand=yes],[have_curand=no])
  489. LDFLAGS="${SAVED_LDFLAGS}"
  490. fi
  491. AC_MSG_CHECKING(whether CURAND is available)
  492. AC_MSG_RESULT($have_curand)
  493. if test x$have_curand = xyes; then
  494. AC_DEFINE(STARPU_HAVE_CURAND,[1], [CURAND is available])
  495. STARPU_CURAND_LDFLAGS="$STARPU_CURAND_LDFLAGS -lcurand"
  496. AC_SUBST(STARPU_CURAND_LDFLAGS)
  497. fi
  498. # Peer transfers are only supported since CUDA 4.0
  499. # Disable them if user explicity wants to disable them
  500. AC_ARG_ENABLE(cuda_memcpy_peer, [AS_HELP_STRING([--disable-cuda-memcpy-peer], [do not allow peer transfers when using CUDA 4.0])],, [enable_cuda_memcpy_peer=yes])
  501. have_cuda_memcpy_peer=no
  502. if test x$enable_cuda_memcpy_peer = xyes -a x$enable_cuda = xyes ; then
  503. SAVED_LDFLAGS="${LDFLAGS}"
  504. LDFLAGS="${LDFLAGS} ${STARPU_CUDA_LDFLAGS}"
  505. AC_CHECK_FUNC([cudaMemcpyPeer], have_cuda_memcpy_peer=yes, have_cuda_memcpy_peer=no)
  506. LDFLAGS="${SAVED_LDFLAGS}"
  507. fi
  508. if test x$have_cuda_memcpy_peer = xyes; then
  509. AC_DEFINE(HAVE_CUDA_MEMCPY_PEER,[],[Peer transfers are supported in CUDA])
  510. fi
  511. if test x$enable_cuda = xyes; then
  512. if test x$starpu_windows != xyes ; then
  513. STARPU_CUDA_LDFLAGS="$STARPU_CUDA_LDFLAGS -lstdc++"
  514. fi
  515. AC_SUBST(STARPU_CUDA_LDFLAGS)
  516. AC_SUBST(STARPU_CUFFT_LDFLAGS)
  517. AC_SUBST(STARPU_CUDA_CPPFLAGS)
  518. fi
  519. AC_ARG_VAR([NVCC], [CUDA compiler])
  520. AC_ARG_VAR([NVCCFLAGS], [CUDA compiler flags])
  521. ###############################################################################
  522. # #
  523. # OpenCL settings #
  524. # #
  525. ###############################################################################
  526. AC_MSG_CHECKING(maximum number of OpenCL devices)
  527. AC_ARG_ENABLE(maxopencldev, [AS_HELP_STRING([--enable-maxopencldev=<number>],
  528. [maximum number of OPENCL devices])],
  529. nmaxopencldev=$enableval, nmaxopencldev=8)
  530. AC_MSG_RESULT($nmaxopencldev)
  531. AC_DEFINE_UNQUOTED(STARPU_MAXOPENCLDEVS, [$nmaxopencldev],
  532. [maximum number of OPENCL devices])
  533. AC_ARG_ENABLE(opencl, [AS_HELP_STRING([--disable-opencl],
  534. [do not use OpenCL device(s)])],, [enable_opencl=maybe])
  535. have_valid_opencl=no
  536. AC_DEFUN([STARPU_CHECK_OPENCL],
  537. [
  538. __opencl_dir=$1
  539. __opencl_include_dir=$2
  540. __opencl_lib_dir=$3
  541. if test "$__opencl_dir" != "no" ; then
  542. AC_MSG_CHECKING(whether OpenCL is available in $__opencl_dir $__opencl_include_dir and $__opencl_lib_dir)
  543. else
  544. AC_MSG_CHECKING(whether OpenCL is available)
  545. fi
  546. AC_MSG_RESULT()
  547. if test "$__opencl_include_dir" = "no" -a "$__opencl_dir" != "no" ; then
  548. __opencl_include_dir="$__opencl_dir/include"
  549. fi
  550. SAVED_CPPFLAGS="$CPPFLAGS"
  551. SAVED_LDFLAGS="${LDFLAGS}"
  552. if test "$__opencl_include_dir" != "no" ; then
  553. CPPFLAGS="${CPPFLAGS} -I$__opencl_include_dir"
  554. fi
  555. AC_CHECK_HEADER([CL/cl.h],[have_valid_opencl=yes],[have_valid_opencl=no])
  556. unset ac_cv_header_CL_cl_h
  557. if test "$have_valid_opencl" = "yes" ; then
  558. if test "$__opencl_lib_dir" != "no"; then
  559. LDFLAGS="${SAVED_LDFLAGS} -L$__opencl_lib_dir"
  560. AC_HAVE_LIBRARY([OpenCL],[have_valid_opencl=yes],[have_valid_opencl=no])
  561. unset ac_cv_lib_OpenCL_main
  562. else
  563. AC_MSG_CHECKING(whether OpenCL is available in $__opencl_dir)
  564. AC_MSG_RESULT()
  565. AC_HAVE_LIBRARY([OpenCL],[have_valid_opencl=yes],[have_valid_opencl=no])
  566. unset ac_cv_lib_OpenCL_main
  567. if test "$have_valid_opencl" = "no" -a "$__opencl_dir" != "no" ; then
  568. for __cuda_libdir in lib64 lib lib/x86 lib/Win32 ; do
  569. __opencl_lib_dir="$__opencl_dir/$__cuda_libdir"
  570. AC_MSG_CHECKING(whether OpenCL is available in $__opencl_dir and $__opencl_lib_dir)
  571. AC_MSG_RESULT()
  572. LDFLAGS="${SAVED_LDFLAGS} -L$__opencl_lib_dir"
  573. AC_HAVE_LIBRARY([OpenCL],[have_valid_opencl=yes],[have_valid_opencl=no])
  574. unset ac_cv_lib_OpenCL_main
  575. if test "$have_valid_opencl" = yes ; then
  576. break
  577. fi
  578. done
  579. else
  580. LDFLAGS="${SAVED_LDFLAGS}"
  581. AC_HAVE_LIBRARY([OpenCL],[have_valid_opencl=yes],[have_valid_opencl=no])
  582. unset ac_cv_lib_OpenCL_main
  583. fi
  584. fi
  585. fi
  586. if test "$have_valid_opencl" = "yes" -a "$__opencl_include_dir" != "no"; then
  587. STARPU_OPENCL_CPPFLAGS="-I$__opencl_include_dir"
  588. AC_CHECK_HEADERS([CL/cl_ext.h])
  589. fi
  590. CPPFLAGS="${SAVED_CPPFLAGS}"
  591. LDFLAGS="${SAVED_LDFLAGS}"
  592. if test "$have_valid_opencl" = "yes" ; then
  593. if test "$__opencl_lib_dir" != "no"; then
  594. STARPU_OPENCL_LDFLAGS="-L$__opencl_lib_dir"
  595. fi
  596. STARPU_OPENCL_LDFLAGS="${STARPU_OPENCL_LDFLAGS} -lOpenCL"
  597. fi
  598. ])
  599. #AC_MSG_CHECKING(whether OpenCL is available)
  600. AC_ARG_WITH(opencl-dir,
  601. [AS_HELP_STRING([--with-opencl-dir=<path>],
  602. [specify OpenCL installation directory])],
  603. [
  604. opencl_dir="$withval"
  605. # in case this was not explicit yet
  606. enable_opencl=yes
  607. ], opencl_dir=no)
  608. AC_ARG_WITH(opencl-include-dir,
  609. [AS_HELP_STRING([--with-opencl-include-dir=<path>],
  610. [specify where OpenCL headers are installed])],
  611. [
  612. opencl_include_dir="$withval"
  613. # in case this was not explicit yet
  614. enable_opencl=yes
  615. ], [opencl_include_dir=no])
  616. AC_ARG_WITH(opencl-lib-dir,
  617. [AS_HELP_STRING([--with-opencl-lib-dir=<path>],
  618. [specify where OpenCL libraries are installed])],
  619. [
  620. opencl_lib_dir="$withval"
  621. # in case this was not explicit yet
  622. enable_opencl=yes
  623. ], [opencl_lib_dir=no])
  624. AC_DEFUN([STARPU_LOOK_FOR_OPENCL],
  625. [
  626. if test "x$has_opencl_being_checked" != "xyes" ; then
  627. STARPU_CHECK_OPENCL("$opencl_dir", "$opencl_include_dir", "$opencl_lib_dir")
  628. if test "$have_valid_opencl" = "no" ; then
  629. for f in "/usr/local/cuda" "/c/cuda" "/cygdrive/c/cuda" "/opt/cuda" "$CUDA_ROOT" "$CUDA_PATH" "$CUDA_INC_PATH/.." "$CUDA_INSTALL_PATH" "$CUDA_TOOLKIT"; do
  630. if test -n "$f" ; then
  631. STARPU_CHECK_OPENCL("$f", "no", "no")
  632. if test "$have_valid_opencl" = "yes" ; then
  633. break
  634. fi
  635. fi
  636. done
  637. fi
  638. has_opencl_being_checked=yes
  639. fi
  640. ])
  641. if test x$enable_opencl = xyes -o x$enable_opencl = xmaybe; then
  642. STARPU_LOOK_FOR_OPENCL()
  643. # in case OpenCL was explicitely required, but is not available, this is an error
  644. if test x$enable_opencl = xyes -a x$have_valid_opencl = xno; then
  645. AC_MSG_ERROR([cannot find OpenCL])
  646. fi
  647. # now we enable OpenCL if and only if a proper setup is available
  648. enable_opencl=$have_valid_opencl
  649. fi
  650. AC_MSG_CHECKING(whether OpenCL should be used)
  651. AC_MSG_RESULT($enable_opencl)
  652. AC_SUBST(STARPU_USE_OPENCL, $enable_opencl)
  653. AM_CONDITIONAL(STARPU_USE_OPENCL, test x$enable_opencl = xyes)
  654. if test x$enable_opencl = xyes ; then
  655. AC_DEFINE(STARPU_USE_OPENCL, [1], [OpenCL support is activated])
  656. STARPU_OPENCL_CPPFLAGS="${STARPU_OPENCL_CPPFLAGS} -DSTARPU_OPENCL_DATADIR=${datarootdir}/starpu/opencl"
  657. AC_SUBST(STARPU_OPENCL_DATAdir, "$(eval echo ${datarootdir}/starpu/opencl/examples)")
  658. AC_SUBST(STARPU_OPENCL_CPPFLAGS)
  659. AC_SUBST(STARPU_OPENCL_LDFLAGS)
  660. fi
  661. ###############################################################################
  662. # #
  663. # General GPU settings #
  664. # #
  665. ###############################################################################
  666. AC_MSG_CHECKING(whether asynchronous copy should be disabled)
  667. AC_ARG_ENABLE(asynchronous-copy, [AS_HELP_STRING([--disable-asynchronous-copy],
  668. [disable asynchronous copy between CPU and GPU])],
  669. enable_asynchronous_copy=$enableval, enable_asynchronous_copy=yes)
  670. disable_asynchronous_copy=no
  671. if test x$enable_asynchronous_copy = xno ; then
  672. disable_asynchronous_copy=yes
  673. fi
  674. AC_MSG_RESULT($disable_asynchronous_copy)
  675. if test x$disable_asynchronous_copy = xyes ; then
  676. AC_DEFINE([STARPU_DISABLE_ASYNCHRONOUS_COPY], [1], [Define to 1 to disable asynchronous copy between CPU and GPU devices])
  677. fi
  678. AC_MSG_CHECKING(whether asynchronous CUDA copy should be disabled)
  679. AC_ARG_ENABLE(asynchronous-cudacopy, [AS_HELP_STRING([--disable-asynchronous-cuda-copy],
  680. [disable asynchronous copy between CPU and CUDA devices])],
  681. enable_asynchronous_cuda_copy=$enableval, enable_asynchronous_cuda_copy=yes)
  682. disable_asynchronous_cuda_copy=no
  683. if test x$enable_asynchronous_cuda_copy = xno ; then
  684. disable_asynchronous_cuda_copy=yes
  685. fi
  686. AC_MSG_RESULT($disable_asynchronous_cuda_copy)
  687. if test x$disable_asynchronous_cuda_copy = xyes ; then
  688. AC_DEFINE([STARPU_DISABLE_ASYNCHRONOUS_CUDA_COPY], [1], [Define to 1 to disable asynchronous copy between CPU and CUDA devices])
  689. fi
  690. AC_MSG_CHECKING(whether asynchronous OpenCL copy should be disabled)
  691. AC_ARG_ENABLE(asynchronous-openclcopy, [AS_HELP_STRING([--disable-asynchronous-opencl-copy],
  692. [disable asynchronous copy between CPU and OPENCL devices])],
  693. enable_asynchronous_opencl_copy=$enableval, enable_asynchronous_opencl_copy=yes)
  694. disable_asynchronous_opencl_copy=no
  695. if test x$enable_asynchronous_opencl_copy = xno ; then
  696. disable_asynchronous_opencl_copy=yes
  697. fi
  698. AC_MSG_RESULT($disable_asynchronous_opencl_copy)
  699. if test x$disable_asynchronous_opencl_copy = xyes ; then
  700. AC_DEFINE([STARPU_DISABLE_ASYNCHRONOUS_OPENCL_COPY], [1], [Define to 1 to disable asynchronous copy between CPU and OpenCL devices])
  701. fi
  702. ###############################################################################
  703. # #
  704. # Cell #
  705. # #
  706. ###############################################################################
  707. # warning: Cell driver has been removed from configure, but as the
  708. # source code is still available, we need to define the minimum
  709. # requirements to compile
  710. AC_DEFINE_UNQUOTED(STARPU_MAXGORDONDEVS, [1], [maximum number of GORDON devices])
  711. ###############################################################################
  712. # #
  713. # Drivers #
  714. # #
  715. ###############################################################################
  716. AC_ARG_ENABLE(opencl-simulator, [AS_HELP_STRING([--enable-opencl-simulator],
  717. [Enable the use of an OpenCL simulator])],
  718. enable_opencl_simulator=$enableval, enable_opencl_simulator=no)
  719. if test x$enable_opencl_simulator = xyes; then
  720. enable_simgrid=yes
  721. AC_DEFINE(STARPU_OPENCL_SIMULATOR, 1, [Define this to enable using an OpenCL simulator])
  722. fi
  723. AC_ARG_ENABLE(simgrid, [AS_HELP_STRING([--enable-simgrid],
  724. [Enable simulating execution in simgrid])],
  725. enable_simgrid=$enableval, enable_simgrid=no)
  726. if test x$enable_simgrid = xyes ; then
  727. if test -n "$SIMGRID_CFLAGS" ; then
  728. CFLAGS="$SIMGRID_CFLAGS $CFLAGS"
  729. fi
  730. if test -n "$SIMGRID_LIBS" ; then
  731. LDFLAGS="$SIMGRID_LIBS $LDFLAGS"
  732. fi
  733. AC_HAVE_LIBRARY([simgrid], [],
  734. [
  735. AC_MSG_ERROR(Simgrid support needs simgrid installed)
  736. ]
  737. )
  738. AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
  739. [[#include <msg/msg.h>]],
  740. [[msg_host_t foo; ]]
  741. )],
  742. [],
  743. [
  744. AC_MSG_ERROR(StarPU needs a version of Simgrid which defines the type msg_host_t (should be any version >= 3.8.1))
  745. ])
  746. AC_DEFINE(STARPU_SIMGRID, 1, [Define this to enable simgrid execution])
  747. # We won't bind or detect anything
  748. with_hwloc=no
  749. fi
  750. AC_SUBST(SIMGRID_CFLAGS)
  751. AC_SUBST(SIMGRID_LIBS)
  752. AC_MSG_CHECKING(whether blocking drivers should be disabled)
  753. AC_ARG_ENABLE(blocking-drivers, [AS_HELP_STRING([--enable-blocking-drivers], [enable blocking drivers])],
  754. enable_blocking=$enableval, enable_blocking=no)
  755. AC_MSG_RESULT($enable_blocking)
  756. if test x$enable_blocking = xno -a x$enable_simgrid != xyes ; then
  757. AC_DEFINE(STARPU_NON_BLOCKING_DRIVERS, [1], [drivers must progress])
  758. fi
  759. ###############################################################################
  760. # #
  761. # Debug and Performance analysis tools #
  762. # #
  763. ###############################################################################
  764. AC_MSG_CHECKING(whether debug mode should be enabled)
  765. AC_ARG_ENABLE(debug, [AS_HELP_STRING([--enable-debug], [enable debug mode])],
  766. enable_debug=$enableval, enable_debug=no)
  767. AC_MSG_RESULT($enable_debug)
  768. if test x$enable_debug = xyes; then
  769. CFLAGS="$CFLAGS -O0"
  770. if test x$enable_simgrid != xyes; then
  771. AC_DEFINE(STARPU_SPINLOCK_CHECK, [1], [check spinlock use])
  772. fi
  773. else
  774. CFLAGS="-O3 $CFLAGS"
  775. fi
  776. CFLAGS+=" -gdwarf-2 -g3 "
  777. AC_MSG_CHECKING(whether extra checks should be performed)
  778. AC_ARG_ENABLE(fast, [AS_HELP_STRING([--enable-fast],
  779. [do not enforce assertions])],
  780. enable_fast=$enableval, enable_fast=no)
  781. AC_MSG_RESULT($enable_fast)
  782. if test x$enable_fast = xyes; then
  783. AC_DEFINE(STARPU_NO_ASSERT, [1], [disable assertions])
  784. fi
  785. AC_MSG_CHECKING(whether debug messages should be displayed)
  786. AC_ARG_ENABLE(verbose, [AS_HELP_STRING([--enable-verbose],
  787. [display verbose debug messages])],
  788. enable_verbose=$enableval, enable_verbose=no)
  789. AC_MSG_RESULT($enable_verbose)
  790. if test x$enable_verbose = xyes; then
  791. AC_DEFINE(STARPU_VERBOSE, [1], [display verbose debug messages])
  792. fi
  793. AC_MSG_CHECKING(whether coverage testing should be enabled)
  794. AC_ARG_ENABLE(coverage, [AS_HELP_STRING([--enable-coverage],
  795. [enable coverage checking])],
  796. enable_coverage=$enableval, enable_coverage=no)
  797. AC_MSG_RESULT($enable_coverage)
  798. AC_SUBST(COVERAGE, $enable_coverage)
  799. AM_CONDITIONAL(STARPU_COVERAGE_ENABLED, [test "x$enable_coverage" = "xyes"])
  800. if test x$enable_coverage = xyes; then
  801. CFLAGS="${CFLAGS} --coverage"
  802. LDFLAGS="${LDFLAGS} --coverage"
  803. fi
  804. # shall we use FxT to generate trace of the execution ?
  805. AC_MSG_CHECKING(whether FxT traces should be generated)
  806. AC_ARG_WITH(fxt, [AS_HELP_STRING([--with-fxt[=<dir>]], [generate fxt traces])],
  807. [
  808. if test x$withval != xno; then
  809. use_fxt=yes
  810. if test x$withval = xyes; then
  811. AC_MSG_RESULT(yes)
  812. use_fxt_from_system=yes
  813. else
  814. # use specified path
  815. # TODO check if the dir is actually containing FxT
  816. use_fxt_from_system=no
  817. fxtdir=$withval
  818. AC_MSG_RESULT(yes using $fxtdir)
  819. AC_SUBST(FXTDIR, $fxtdir)
  820. fi
  821. else
  822. use_fxt=no
  823. AC_MSG_RESULT(no)
  824. fi
  825. ],
  826. [
  827. use_fxt=no
  828. AC_MSG_RESULT(no)
  829. ])
  830. AC_SUBST(STARPU_USE_FXT, $use_fxt)
  831. AM_CONDITIONAL(STARPU_USE_FXT, test x$use_fxt = xyes)
  832. if test x$use_fxt = xyes; then
  833. AC_DEFINE(STARPU_USE_FXT, [1], [enable FxT traces])
  834. AC_DEFINE(CONFIG_FUT, [1], [enable FUT traces])
  835. if test x$use_fxt_from_system = xno; then
  836. save_PKG_CONFIG_PATH="$PKG_CONFIG_PATH"
  837. PKG_CONFIG_PATH="$fxtdir/lib/pkgconfig:$PKG_CONFIG_PATH"
  838. PKG_CHECK_MODULES([FXT], [fxt], , [
  839. AC_MSG_WARN([Old FxT without fxt.pc file, hoping link will succeed])
  840. FXT_CFLAGS="-I$fxtdir/include/ "
  841. FXT_LDFLAGS="-L$fxtdir/lib/"
  842. AC_ARG_VAR(FXT_LDFLAGS)
  843. FXT_LIBS="-lfxt"
  844. ])
  845. PKG_CONFIG_PATH="$save_PKG_CONFIG_PATH"
  846. else
  847. PKG_CHECK_MODULES([FXT], [fxt])
  848. fi
  849. save_LIBS="$LIBS"
  850. LIBS="$LIBS $FXT_LIBS"
  851. save_LDFLAGS="$LDFLAGS"
  852. LDFLAGS="$LDFLAGS $FXT_LDFLAGS"
  853. AC_CHECK_FUNCS([enable_fut_flush])
  854. AC_CHECK_FUNCS([fut_set_filename])
  855. LDFLAGS="$save_LDFLAGS"
  856. LIBS="$save_LIBS"
  857. save_CFLAGS="$CFLAGS"
  858. CFLAGS="$CFLAGS $FXT_CFLAGS"
  859. AC_CHECK_DECLS([enable_fut_flush])
  860. AC_CHECK_DECLS([fut_set_filename])
  861. CFLAGS="$save_CFLAGS"
  862. ##########################################
  863. # Poti is a library to generate paje trace files
  864. ##########################################
  865. PKG_CHECK_MODULES([POTI], [poti], [
  866. AC_DEFINE(STARPU_HAVE_POTI, [1], [Define to 1 if you have libpoti])
  867. ], [:])
  868. FXT_CFLAGS="$FXT_CFLAGS $POTI_CFLAGS"
  869. FXT_LIBS="$FXT_LIBS $POTI_LIBS"
  870. fi
  871. AC_MSG_CHECKING(whether performance debugging should be enabled)
  872. AC_ARG_ENABLE(perf-debug, [AS_HELP_STRING([--enable-perf-debug],
  873. [enable performance debugging through gprof])],
  874. enable_perf_debug=$enableval, enable_perf_debug=no)
  875. AC_MSG_RESULT($enable_perf_debug)
  876. AC_SUBST(STARPU_PERF_DEBUG, $enable_perf_debug)
  877. if test x$enable_perf_debug = xyes; then
  878. AC_DEFINE(STARPU_PERF_DEBUG, [1], [enable performance debug])
  879. CPPFLAGS="${CPPFLAGS} -pg -fprofile-arcs "
  880. LDFLAGS="${LDFLAGS} -pg -fprofile-arcs "
  881. fi
  882. AC_MSG_CHECKING(whether performance model debugging should be enabled)
  883. AC_ARG_ENABLE(model-debug, [AS_HELP_STRING([--enable-model-debug],
  884. [enable performance model debugging])],
  885. enable_model_debug=$enableval, enable_model_debug=no)
  886. AC_MSG_RESULT($enable_model_debug)
  887. if test x$enable_model_debug = xyes; then
  888. AC_DEFINE(STARPU_MODEL_DEBUG, [1], [enable performance model debug])
  889. fi
  890. AC_MSG_CHECKING(whether statistics should be generated)
  891. AC_ARG_ENABLE(stats, [AS_HELP_STRING([--enable-stats],
  892. [enable statistics])],
  893. enable_stats=$enableval, enable_stats=no)
  894. AC_MSG_RESULT($enable_stats)
  895. AC_SUBST(STATS, $enable_stats)
  896. AC_SUBST(STARPU_ENABLE_STATS, $enable_stats)
  897. if test x$enable_stats = xyes; then
  898. AC_DEFINE(STARPU_ENABLE_STATS, [1], [enable statistics])
  899. fi
  900. AC_MSG_CHECKING(whether memory stats should be displayed)
  901. AC_ARG_ENABLE(memory-stats, [AS_HELP_STRING([--enable-memory-stats],
  902. [enable memory stats])],
  903. enable_memory_stats=$enableval, enable_memory_stats=no)
  904. AC_MSG_RESULT($enable_memory_stats)
  905. if test x$enable_memory_stats = xyes; then
  906. AC_DEFINE(STARPU_MEMORY_STATS, [1], [enable memory stats])
  907. fi
  908. AC_CHECK_HEADERS([glpk.h], [AC_DEFINE([STARPU_HAVE_GLPK_H], [1], [Define to 1 if you have the <glpk.h> header file.])])
  909. STARPU_HAVE_LIBRARY(GLPK, [glpk])
  910. AC_CHECK_HEADERS([Ayudame.h])
  911. ###############################################################################
  912. # #
  913. # Miscellaneous options for StarPU #
  914. # #
  915. ###############################################################################
  916. AC_MSG_CHECKING(how many buffers can be manipulated per task)
  917. AC_ARG_ENABLE(maxbuffers, [AS_HELP_STRING([--enable-maxbuffers=<nbuffers>],
  918. [maximum number of buffers per task])],
  919. nmaxbuffers=$enableval, nmaxbuffers=8)
  920. AC_MSG_RESULT($nmaxbuffers)
  921. AC_DEFINE_UNQUOTED(STARPU_NMAXBUFS, [$nmaxbuffers],
  922. [how many buffers can be manipulated per task])
  923. if test x$enable_simgrid = xyes ; then
  924. maxnodes=16
  925. else
  926. # We have one memory node shared by all CPU workers, one node per GPU
  927. maxnodes=1
  928. if test x$enable_cuda = xyes ; then
  929. # we could have used nmaxcudadev + 1, but this would certainly give an
  930. # odd number.
  931. maxnodes=`expr $nodes + $nmaxcudadev`
  932. fi
  933. if test x$enable_opencl = xyes ; then
  934. # we could have used nmaxcudadev + 1, but this would certainly give an
  935. # odd number.
  936. maxnodes=`expr $nodes + $nmaxopencldev`
  937. fi
  938. # todo: set maxnodes to the next power of 2 greater than maxnodes
  939. fi
  940. AC_MSG_CHECKING(maximum number of memory nodes)
  941. AC_MSG_RESULT($maxnodes)
  942. AC_DEFINE_UNQUOTED(STARPU_MAXNODES, [$maxnodes],
  943. [maximum number of memory nodes])
  944. AC_MSG_CHECKING(whether allocation cache should be used)
  945. AC_ARG_ENABLE(allocation-cache, [AS_HELP_STRING([--enable-allocation-cache],
  946. [enable data allocation cache])],
  947. enable_allocation_cache=$enableval, enable_allocation_cache=no)
  948. AC_MSG_RESULT($enable_allocation_cache)
  949. if test x$enable_allocation_cache = xyes; then
  950. AC_DEFINE(STARPU_USE_ALLOCATION_CACHE, [1], [enable data allocation cache])
  951. fi
  952. AC_ARG_WITH(perf-model-dir, [AS_HELP_STRING([--with-perf-model-dir=<dir>], [specify where performance models shoulds be stored])],
  953. [
  954. if test x$withval = xno; then
  955. AC_MSG_ERROR(--without-perf-model-dir is not a valid option)
  956. fi
  957. perf_model_dir="$withval"
  958. have_explicit_perf_model_dir=yes
  959. AC_DEFINE_UNQUOTED(STARPU_PERF_MODEL_DIR, ["$perf_model_dir"], [performance models location])
  960. ], [
  961. # by default, we put the performance models in
  962. # $HOME/.starpu/sampling/
  963. have_explicit_perf_model_dir=no
  964. perf_model_dir="\$HOME/.starpu/sampling/"
  965. ]
  966. )
  967. AC_MSG_CHECKING(using explicit performance model location)
  968. AC_MSG_RESULT($have_explicit_perf_model_dir)
  969. AC_MSG_CHECKING(performance models location)
  970. AC_MSG_RESULT($perf_model_dir)
  971. # On many multicore CPUs, clock cycles are not synchronized
  972. AC_CHECK_LIB([rt], [clock_gettime])
  973. AC_CHECK_FUNCS([clock_gettime])
  974. # Compute the maximum number of workers (we round it to 16 for alignment
  975. # purposes).
  976. nmaxworkers=`expr 16 \* \( \( $maxcpus + $nmaxcudadev + $nmaxopencldev + 15 \) / 16 \) `
  977. AC_MSG_CHECKING(Maximum number of workers)
  978. AC_MSG_RESULT($nmaxworkers)
  979. AC_DEFINE_UNQUOTED(STARPU_NMAXWORKERS, [$nmaxworkers], [Maximum number of workers])
  980. # Computes the maximum number of implementations per arch
  981. AC_MSG_CHECKING(maximum number of implementations)
  982. AC_ARG_ENABLE(maximplementations, [AS_HELP_STRING([--enable-maximplementations=<number>],
  983. [maximum number of implementations])],
  984. maximplementations=$enableval, maximplementations=8)
  985. AC_MSG_RESULT($maximplementations)
  986. AC_DEFINE_UNQUOTED(STARPU_MAXIMPLEMENTATIONS, [$maximplementations],
  987. [maximum number of implementations])
  988. ###############################################################################
  989. # #
  990. # MPI #
  991. # #
  992. ###############################################################################
  993. AC_ARG_WITH(mpicc, [AS_HELP_STRING([--with-mpicc[=<path to mpicc>]],
  994. [Path of the mpicc compiler])],
  995. [
  996. if test x$withval = xyes; then
  997. AC_MSG_ERROR(--with-mpicc must be given a pathname)
  998. else
  999. mpicc_path=$withval
  1000. fi
  1001. ],
  1002. [
  1003. # nothing was specified: default value is used
  1004. AC_PATH_PROG(mpicc_path, mpicc, [no], [])
  1005. ])
  1006. # We test if the MPICC compiler exists
  1007. if test ! -x $mpicc_path; then
  1008. #MPICC does not exists or is not executable
  1009. AC_MSG_RESULT(The mpicc compiler is not valid)
  1010. use_mpi=no
  1011. else
  1012. use_mpi=yes
  1013. fi
  1014. AC_MSG_CHECKING(mpicc path)
  1015. AC_MSG_RESULT($mpicc_path)
  1016. AC_SUBST(MPICC, $mpicc_path)
  1017. if test x$use_mpi = xyes; then
  1018. cc_or_mpicc=$mpicc_path
  1019. # For some reason, libtool uses gcc instead of mpicc when linking
  1020. # libstarpumpi.
  1021. # On Darwin (and maybe other systems ?) the linker will fail (undefined
  1022. # references to MPI_*). We manually add the required flags to fix this
  1023. # issue.
  1024. AC_SUBST(MPICC_LDFLAGS, `$mpicc_path --showme:link`)
  1025. else
  1026. cc_or_mpicc=$CC
  1027. fi
  1028. AC_SUBST(CC_OR_MPICC, $cc_or_mpicc)
  1029. # If the user specifically asks for it, or if we are in a developer checkout, we enable mpi check
  1030. AC_ARG_ENABLE(mpi-check, AC_HELP_STRING([--enable-mpi-check], [Enable execution of MPI testcases]))
  1031. running_mpi_check=no
  1032. if test -d "$srcdir/.svn" -o -d "$srcdir/.git" ; then
  1033. running_mpi_check=yes
  1034. fi
  1035. if test x$enable_mpi_check = xyes ; then
  1036. running_mpi_check=yes
  1037. fi
  1038. if test x$enable_mpi_check = xno ; then
  1039. running_mpi_check=no
  1040. fi
  1041. # Check if mpiexec is available
  1042. AC_ARG_WITH(mpiexec, [AS_HELP_STRING([--with-mpiexec[=<path to mpiexec>]],
  1043. [Path of mpiexec])],
  1044. [
  1045. if test x$withval = xyes; then
  1046. AC_MSG_ERROR(--with-mpiexec must be given a pathname)
  1047. else
  1048. mpiexec_path=$withval
  1049. fi
  1050. ],
  1051. [
  1052. # nothing was specified: look in the path
  1053. AC_PATH_PROG(mpiexec_path, mpiexec, [no], [$(dirname $mpicc_path):$PATH])
  1054. ])
  1055. AC_MSG_CHECKING(whether mpiexec is available)
  1056. AC_MSG_RESULT($mpiexec_path)
  1057. # We test if MPIEXEC exists
  1058. if test ! -x $mpiexec_path; then
  1059. #MPIEXEC does not exists or is not executable
  1060. AC_MSG_RESULT(The mpiexec script is not valid)
  1061. running_mpi_check=no
  1062. mpiexec_path=""
  1063. fi
  1064. AM_CONDITIONAL(STARPU_MPI_CHECK, test x$running_mpi_check = xyes)
  1065. if test x$use_mpi = xyes; then
  1066. AC_MSG_CHECKING(whether MPI tests should be run)
  1067. AC_MSG_RESULT($running_mpi_check)
  1068. AC_SUBST(MPIEXEC,$mpiexec_path)
  1069. fi
  1070. AC_MSG_CHECKING(whether the StarPU MPI library should be generated)
  1071. AC_MSG_RESULT($use_mpi)
  1072. AC_SUBST(USE_MPI, $use_mpi)
  1073. AM_CONDITIONAL(USE_MPI, test x$use_mpi = xyes)
  1074. if test x$use_mpi = xyes; then
  1075. AC_DEFINE(STARPU_USE_MPI,[],[whether the StarPU MPI library is available])
  1076. fi
  1077. ###############################################################################
  1078. # #
  1079. # StarPU-Top #
  1080. # #
  1081. ###############################################################################
  1082. AC_ARG_ENABLE([starpu-top],
  1083. [AS_HELP_STRING([--disable-starpu-top],
  1084. [build StarPU-Top])],
  1085. [enable_starpu_top="$enableval"],
  1086. [enable_starpu_top="maybe"])
  1087. # Check whether StarPU-Top can be built
  1088. AC_MSG_CHECKING(for StarPU-Top)
  1089. if test "x$enable_starpu_top" != "xno" ; then
  1090. can_build_starpu_top=no
  1091. AC_PATH_PROGS([QMAKE], [qmake-qt4 qmake], [not-found])
  1092. if test x$QMAKE != xnot-found; then
  1093. QMAKE_VERSION=`$QMAKE --version 2>&1 | head -n 1 | cut -d '.' -f 1 | cut -d ' ' -f 3`
  1094. if test $QMAKE_VERSION -ge 2 ; then
  1095. PKG_CHECK_EXISTS([QtGui QtNetwork QtOpenGL QtSql], [
  1096. QT_MAJVERSION=`$PKG_CONFIG --modversion QtGui | cut -d '.' -f 1`
  1097. QT_MINVERSION=`$PKG_CONFIG --modversion QtGui | cut -d '.' -f 2`
  1098. if test $QT_MAJVERSION -gt 4 -o \( $QT_MAJVERSION -eq 4 -a $QT_MINVERSION -ge 7 \) ; then
  1099. can_build_starpu_top=yes
  1100. fi
  1101. QWT_PRI=embed
  1102. AC_ARG_WITH(qwt-include-dir,
  1103. [AS_HELP_STRING([--with-qwt-include-dir=<path>],
  1104. [specify installed libqwt include path])],
  1105. [
  1106. STARPU_QWT_INCLUDE="$withval"
  1107. AC_SUBST(STARPU_QWT_INCLUDE)
  1108. QWT_PRI=system
  1109. ])
  1110. AC_ARG_WITH(qwt-lib-dir,
  1111. [AS_HELP_STRING([--with-qwt-lib-dir=<path>],
  1112. [specify installed libqwt library path])],
  1113. [
  1114. STARPU_QWT_LDFLAGS="-L$withval"
  1115. QWT_PRI=system
  1116. ])
  1117. AC_ARG_WITH(qwt-lib,
  1118. [AS_HELP_STRING([--with-qwt-lib=<name>],
  1119. [specify installed libqwt library name])],
  1120. [
  1121. STARPU_QWT_LDFLAGS="${STARPU_QWT_LDFLAGS} -l$withval"
  1122. QWT_PRI=system
  1123. ])
  1124. AC_SUBST(STARPU_QWT_LDFLAGS)
  1125. AC_SUBST(QWT_PRI)
  1126. ])
  1127. fi
  1128. fi
  1129. fi
  1130. if test "x$enable_starpu_top" != "xno" ; then
  1131. build_starpu_top=$can_build_starpu_top
  1132. else
  1133. build_starpu_top=no
  1134. fi
  1135. AC_SUBST(STARPU_USE_TOP, $build_starpu_top)
  1136. AM_CONDITIONAL(BUILD_STARPU_TOP, test "x$build_starpu_top" = "xyes")
  1137. if test "x$build_starpu_top" = "xyes"; then
  1138. AC_DEFINE(STARPU_USE_TOP, [1], [StarPU-Top is activated])
  1139. fi
  1140. ###############################################################################
  1141. # #
  1142. # Flags for C Compiler #
  1143. # #
  1144. ###############################################################################
  1145. # IS_SUPPORTED_CFLAG(flag)
  1146. # ------------------------
  1147. # Check if the CFLAGS `flag' is supported by the compiler
  1148. AC_DEFUN([IS_SUPPORTED_CFLAG],
  1149. [
  1150. AC_REQUIRE([AC_PROG_CC])
  1151. AC_MSG_CHECKING([whether compiler support $1])
  1152. SAVED_CFLAGS="$CFLAGS"
  1153. CFLAGS="$1" # -we10006"
  1154. AC_COMPILE_IFELSE(
  1155. AC_LANG_PROGRAM(
  1156. [[]],
  1157. [[
  1158. AC_LANG_SOURCE([
  1159. const char *hello = "Hello World";
  1160. ])
  1161. ]]
  1162. ),
  1163. [
  1164. GLOBAL_AM_CFLAGS="$GLOBAL_AM_CFLAGS $1"
  1165. AC_MSG_RESULT(yes)
  1166. ],
  1167. AC_MSG_RESULT(no)
  1168. )
  1169. CFLAGS="$SAVED_CFLAGS"
  1170. ])
  1171. IS_SUPPORTED_CFLAG(-W)
  1172. IS_SUPPORTED_CFLAG(-Wall)
  1173. IS_SUPPORTED_CFLAG(-Wextra)
  1174. AC_SUBST(GLOBAL_AM_CFLAGS)
  1175. if test "x$STARPU_DEVEL" != x; then
  1176. AC_DEFINE(STARPU_DEVEL, [1], [enable developer warnings])
  1177. fi
  1178. # Same value as Automake's, for use in other places.
  1179. pkglibdir="\${libdir}/$PACKAGE"
  1180. AC_SUBST([pkglibdir])
  1181. ###############################################################################
  1182. # #
  1183. # GCC extensions #
  1184. # #
  1185. ###############################################################################
  1186. AC_ARG_ENABLE([gcc-extensions],
  1187. [AS_HELP_STRING([--enable-gcc-extensions],
  1188. [build the GCC plug-in that provides C language extensions (experimental)])],
  1189. [enable_gcc_plugin="$enableval"],
  1190. [enable_gcc_plugin="maybe"])
  1191. if test "x$enable_gcc_plugin" = "xyes" -o "x$enable_gcc_plugin" = "xmaybe" ; then
  1192. STARPU_GCC_PLUGIN_SUPPORT
  1193. if test "x$ac_cv_have_gcc_plugins" = "xno" ; then
  1194. if test "x$enable_gcc_plugin" = "xyes" ; then
  1195. # Since this was explicitly asked for, error out.
  1196. AC_MSG_ERROR([This compiler lacks GCC plug-in support.])
  1197. else
  1198. AC_MSG_WARN([GCC plug-ins not supported; StarPU's GCC plug-in will not be built])
  1199. fi
  1200. else
  1201. # What GCC version are we using?
  1202. STARPU_GCC_VERSION
  1203. # The `.so' itself cannot be called `starpu-gcc.so' (because
  1204. # `-fplugin-arg-' option names and such must match the `.so'
  1205. # name), so use a meaningful directory name.
  1206. gccplugindir="\${pkglibdir}/${STARPU_EFFECTIVE_VERSION}/gcc/${STARPU_GCC_VERSION_MAJOR}.${STARPU_GCC_VERSION_MINOR}"
  1207. AC_SUBST([gccplugindir])
  1208. # Lines to be inserted in the `.pc' file.
  1209. GCC_PLUGIN_DIR_PKGCONFIG="gccplugindir=$gccplugindir"
  1210. GCC_PLUGIN_PKGCONFIG="gccplugin=\${gccplugindir}/starpu.so"
  1211. AC_SUBST([GCC_PLUGIN_DIR_PKGCONFIG])
  1212. AC_SUBST([GCC_PLUGIN_PKGCONFIG])
  1213. fi
  1214. fi
  1215. AM_CONDITIONAL([HAVE_PTR_DEREFS_MAY_ALIAS_P],
  1216. [test "x$ac_cv_have_decl_ptr_derefs_may_alias_p" = "xyes"])
  1217. if test "x$ac_cv_have_gcc_plugins" = "xyes" ; then
  1218. build_gcc_plugin="yes"
  1219. # GNU Guile 1.8/2.0 is used to run the test suite.
  1220. AC_PATH_PROG([GUILE], [guile])
  1221. if test "x$GUILE" != "x"; then
  1222. if test "x$enable_cpu" = "xyes"; then
  1223. run_gcc_plugin_test_suite="yes"
  1224. else
  1225. AC_MSG_WARN([CPU back-end disabled; GCC plug-in test suite will not be run])
  1226. run_gcc_plugin_test_suite="no"
  1227. fi
  1228. else
  1229. run_gcc_plugin_test_suite="no"
  1230. fi
  1231. else
  1232. build_gcc_plugin="no"
  1233. run_gcc_plugin_test_suite="no"
  1234. fi
  1235. # Bison is used to generate the C expression parser. The generated
  1236. # parser is part of the distribution, though.
  1237. AM_MISSING_PROG([YACC], [bison])
  1238. AM_CONDITIONAL([BUILD_GCC_PLUGIN], [test "x$build_gcc_plugin" = "xyes"])
  1239. AM_CONDITIONAL([RUN_GCC_PLUGIN_TESTS],
  1240. [test "x$run_gcc_plugin_test_suite" = "xyes"])
  1241. ###############################################################################
  1242. # #
  1243. # SOCL interface #
  1244. # #
  1245. ###############################################################################
  1246. AC_ARG_ENABLE([socl],
  1247. [AS_HELP_STRING([--enable-socl],
  1248. [build the OpenCL interface (experimental)])],
  1249. [enable_socl="$enableval"],
  1250. [enable_socl="maybe"])
  1251. AC_MSG_CHECKING(for SOCL)
  1252. # in case SOCL was explicitely required, but is not available, this is an error
  1253. if test "x$enable_socl" = "xyes" -a "$have_valid_opencl" = "no" ; then
  1254. AC_MSG_ERROR([SOCL cannot be enabled without OpenCL])
  1255. fi
  1256. # now we enable SOCL if and only if a proper setup is available
  1257. if test "x$enable_socl" = "xyes" -o "x$enable_socl" = "xmaybe" ; then
  1258. build_socl=$have_valid_opencl
  1259. else
  1260. build_socl=no
  1261. fi
  1262. AC_MSG_RESULT($build_socl)
  1263. AM_CONDITIONAL([BUILD_SOCL], [test "x$build_socl" = "xyes"])
  1264. AM_CONDITIONAL([STARPU_USE_SOCL], [test "x$build_socl" = "xyes"])
  1265. if test "$build_socl" = "yes" ; then
  1266. AC_CHECK_FUNCS([clGetExtensionFunctionAddressForPlatform])
  1267. if test -z "$SOCL_OCL_LIB_OPENCL" ; then
  1268. run_socl_check=no
  1269. else
  1270. run_socl_check=yes
  1271. AC_SUBST(SOCL_OCL_LIB_OPENCL)
  1272. fi
  1273. else
  1274. run_socl_check=no
  1275. fi
  1276. ###############################################################################
  1277. # #
  1278. # Debugging #
  1279. # #
  1280. ###############################################################################
  1281. AC_PATH_PROG([GDB], [gdb], [not-found])
  1282. if test "x$GDB" != "xnot-found"; then
  1283. AC_DEFINE_UNQUOTED([STARPU_GDB_PATH], ["$GDB"],
  1284. [Path to the GNU debugger.])
  1285. fi
  1286. ###############################################################################
  1287. # #
  1288. # Examples #
  1289. # #
  1290. ###############################################################################
  1291. AC_ARG_ENABLE(build-examples, [AS_HELP_STRING([--disable-build-examples],
  1292. [disable building of examples])],
  1293. enable_build_examples=$enableval, enable_build_examples=yes)
  1294. # check stuff for examples (todo)
  1295. AM_CONDITIONAL(BUILD_EXAMPLES, [test x$enable_build_examples != xno])
  1296. AC_ARG_ENABLE(opengl-render, [AS_HELP_STRING([--enable-opengl-render],
  1297. [enable OpenGL rendering of some examples])],
  1298. enable_opengl_render=$enableval, enable_opengl_render=no)
  1299. if test x$enable_opengl_render = xyes; then
  1300. STARPU_CHECK_LIB(OPENGL_RENDER, glut, glutInit,,AC_MSG_ERROR([cannot find glut]))
  1301. STARPU_CHECK_LIB(OPENGL_RENDER, GL, glXCreateContext,,AC_MSG_ERROR([cannot find GL]))
  1302. STARPU_CHECK_LIB(OPENGL_RENDER, GLU, gluLookAt,,AC_MSG_ERROR([cannot find GLU]))
  1303. AC_DEFINE(STARPU_OPENGL_RENDER, [1], [enable OpenGL rendering of some examples])
  1304. fi
  1305. AC_MSG_CHECKING(whether OpenGL rendering is enabled)
  1306. AC_SUBST(STARPU_OPENGL_RENDER, $enable_opengl_render)
  1307. AC_MSG_RESULT($enable_opengl_render)
  1308. AM_CONDITIONAL([HAVE_OPENGL], [test "x$enable_opengl_render" = xyes])
  1309. AC_PATH_XTRA
  1310. if test "x$no_x" != "xyes"; then
  1311. AC_DEFINE(STARPU_HAVE_X11, [1], [enable X11])
  1312. fi
  1313. AM_CONDITIONAL([HAVE_X11], [test "x$no_x" != "xyes"])
  1314. # In case there are BLAS kernels that are used by the example applications
  1315. # we may specify which library to use. Note that this is not used for StarPU
  1316. # itself.
  1317. blas_lib=maybe
  1318. AC_ARG_ENABLE(blas-lib,
  1319. [ --enable-blas-lib[=blaslibname]:
  1320. none [default]: no BLAS lib is used
  1321. atlas: use ATLAS library
  1322. goto: use GotoBLAS library],
  1323. [
  1324. if test "x$enableval" = "xatlas" ; then
  1325. blas_lib=atlas
  1326. elif test "x$enableval" = "xgoto" ; then
  1327. blas_lib=goto
  1328. elif test "x$enableval" = "xnone" ; then
  1329. blas_lib=none
  1330. elif test x$enableval = xno; then
  1331. blas_lib=none
  1332. else
  1333. echo
  1334. echo "Error!"
  1335. echo "Unknown BLAS library"
  1336. exit -1
  1337. fi
  1338. ])
  1339. if test x$blas_lib = xmaybe -o x$blas_lib = xgoto; then
  1340. AC_ARG_WITH(goto-dir, [AS_HELP_STRING([--with-goto-dir=<dir>], [specify GotoBLAS lib location])],
  1341. [
  1342. blas_lib=goto
  1343. gotodir=$withval
  1344. AC_SUBST(GOTODIR, $gotodir)
  1345. CPPFLAGS="${CPPFLAGS} -I$gotodir/ "
  1346. LDFLAGS="${LDFLAGS} -L$gotodir/ "
  1347. ]
  1348. )
  1349. if test x$blas_lib = xgoto; then
  1350. STARPU_CHECK_LIB(BLAS, gfortran, main,,)
  1351. STARPU_CHECK_LIB(BLAS, ifcore, main,,)
  1352. # Perhaps that GotoBLAS2 is available instead (so that we have libgotoblas2.{so,a})
  1353. STARPU_CHECK_LIB(BLAS, goto2, sgemm_,, [havegoto2=no], [$STARPU_BLAS_LDFLAGS])
  1354. if test x$havegoto2 = xno; then
  1355. STARPU_CHECK_LIB(BLAS, goto, sgemm_,,AC_MSG_ERROR([cannot find goto lib]), [$STARPU_BLAS_LDFLAGS])
  1356. fi
  1357. AC_DEFINE(STARPU_GOTO, [1], [use STARPU_GOTO library])
  1358. fi
  1359. fi
  1360. if test x$blas_lib = xmaybe -o x$blas_lib = xatlas; then
  1361. AC_ARG_WITH(atlas-dir, [AS_HELP_STRING([--with-atlas-dir=<dir>], [specify ATLAS lib location])],
  1362. [
  1363. AC_MSG_CHECKING(STARPU_ATLAS location)
  1364. blas_lib=atlas
  1365. atlasdir=$withval
  1366. AC_MSG_RESULT($atlasdir)
  1367. AC_SUBST(ATLASDIR, $atlasdir)
  1368. CPPFLAGS="${CPPFLAGS} -I$atlasdir/include/ "
  1369. LDFLAGS="${LDFLAGS} -L$atlasdir/lib/ "
  1370. ]
  1371. )
  1372. if test x$blas_lib = xatlas; then
  1373. # test whether STARPU_ATLAS is actually available
  1374. AC_CHECK_HEADER([cblas.h],,AC_MSG_ERROR([cannot find atlas headers]))
  1375. STARPU_CHECK_LIB(BLAS, atlas, ATL_sgemm,,AC_MSG_ERROR([cannot find atlas lib]),)
  1376. STARPU_CHECK_LIB(BLAS, cblas, cblas_sgemm,,AC_MSG_ERROR([cannot find atlas lib]),[-latlas])
  1377. AC_DEFINE(STARPU_ATLAS, [1], [use STARPU_ATLAS library])
  1378. fi
  1379. fi
  1380. if test x$blas_lib = xmaybe; then
  1381. # Should we use MKL ?
  1382. AC_ARG_WITH(mkl-cflags, [AS_HELP_STRING([--with-mkl-cflags], [specify MKL compilation flags])],
  1383. [
  1384. CPPFLAGS="${CPPFLAGS} $withval"
  1385. blas_lib=mkl
  1386. ])
  1387. AC_ARG_WITH(mkl-ldflags, [AS_HELP_STRING([--with-mkl-ldflags], [specify MKL linking flags])],
  1388. [
  1389. LDFLAGS="${LDFLAGS} $withval"
  1390. blas_lib=mkl
  1391. ])
  1392. if test x$blas_lib = xmkl; then
  1393. AC_DEFINE(STARPU_MKL, [1], [use MKL library])
  1394. fi
  1395. fi
  1396. if test x$blas_lib = xmaybe; then
  1397. #perhaps it is possible to use some BLAS lib from the system
  1398. use_system_blas=no
  1399. STARPU_SEARCH_LIBS(BLAS,[sgemm_],[blas],use_system_blas=yes,,)
  1400. if test x$use_system_blas = xyes; then
  1401. AC_DEFINE(STARPU_SYSTEM_BLAS, [1], [use refblas library])
  1402. blas_lib=system
  1403. elif test x"$BLAS_LIBS" != x; then
  1404. AC_DEFINE(STARPU_SYSTEM_BLAS, [1], [use user defined library])
  1405. STARPU_BLAS_LDFLAGS="$BLAS_LIBS"
  1406. AC_SUBST(STARPU_BLAS_LDFLAGS)
  1407. blas_lib=system
  1408. AC_ARG_VAR([BLAS_LIBS], [linker flags for blas])
  1409. else
  1410. blas_lib=none
  1411. fi
  1412. fi
  1413. AM_CONDITIONAL(ATLAS_BLAS_LIB, test x$blas_lib = xatlas)
  1414. AM_CONDITIONAL(GOTO_BLAS_LIB, test x$blas_lib = xgoto)
  1415. AM_CONDITIONAL(MKL_BLAS_LIB, test x$blas_lib = xmkl)
  1416. AM_CONDITIONAL(SYSTEM_BLAS_LIB, test x$blas_lib = xsystem)
  1417. AM_CONDITIONAL(NO_BLAS_LIB, test x$blas_lib = xnone)
  1418. AC_MSG_CHECKING(which BLAS lib should be used)
  1419. AC_MSG_RESULT($blas_lib)
  1420. AC_SUBST(BLAS_LIB,$blas_lib)
  1421. ##########################################
  1422. # FFT #
  1423. ##########################################
  1424. have_fftw=no
  1425. have_fftwf=no
  1426. have_fftwl=no
  1427. fft_support=no
  1428. AC_ARG_ENABLE(starpufft, [AS_HELP_STRING([--disable-starpufft],
  1429. [Disable build of StarPU-FFT])],
  1430. enable_starpufft=$enableval,enable_starpufft=yes)
  1431. PKG_CHECK_MODULES([FFTW], [fftw3], [
  1432. AC_DEFINE([STARPU_HAVE_FFTW], [1], [Define to 1 if you have the libfftw3 library.])
  1433. AC_SUBST([STARPU_HAVE_FFTW], [1])
  1434. have_fftw=yes
  1435. ], [:])
  1436. AM_CONDITIONAL(STARPU_HAVE_FFTW, [test x$have_fftw = xyes])
  1437. PKG_CHECK_MODULES([FFTWF], [fftw3f], [
  1438. AC_DEFINE([STARPU_HAVE_FFTWF], [1], [Define to 1 if you have the libfftw3f library.])
  1439. AC_SUBST([STARPU_HAVE_FFTWF], [1])
  1440. have_fftwf=yes
  1441. ], [:])
  1442. AM_CONDITIONAL(STARPU_HAVE_FFTWF, [test x$have_fftwf = xyes])
  1443. PKG_CHECK_MODULES([FFTWL], [fftw3l], [
  1444. AC_DEFINE([STARPU_HAVE_FFTWL], [1], [Define to 1 if you have the libfftw3l library.])
  1445. AC_SUBST([HAVE_FFTWFL], [1])
  1446. have_fftwl=yes
  1447. ], [:])
  1448. AM_CONDITIONAL(STARPU_HAVE_FFTWL, [test x$have_fftwl = xyes])
  1449. if test x$enable_starpufft = xyes -a \( \( x$enable_cpu = xyes -a x$have_fftw = xyes -a x$have_fftwf = xyes \) -o x$have_cufftdoublecomplex = xyes \); then
  1450. fft_support=yes
  1451. fi
  1452. AM_CONDITIONAL(BUILD_STARPUFFT, [test x$fft_support = xyes])
  1453. ##########################################
  1454. # hwloc #
  1455. ##########################################
  1456. AC_ARG_WITH([hwloc],
  1457. [AS_HELP_STRING([--without-hwloc], [Disable hwloc (enabled by default)])],
  1458. [
  1459. if test x$withval != xno; then
  1460. if test "$withval" = "yes" ; then
  1461. use_hwloc_from_system=yes
  1462. use_hwloc=yes
  1463. else
  1464. # use specified path
  1465. use_hwloc_from_system=no
  1466. if test ! -d "$withval" ; then
  1467. AC_MSG_ERROR("Directory specified for hwloc <$withval> does not exist")
  1468. fi
  1469. hwloc_dir=$withval
  1470. use_hwloc=yes
  1471. fi
  1472. else
  1473. use_hwloc=no
  1474. fi
  1475. ],
  1476. [
  1477. use_hwloc=maybe
  1478. use_hwloc_from_system=yes
  1479. ])
  1480. SAVED_LDFLAGS="${LDFLAGS}"
  1481. SAVED_CPPFLAGS="${CPPFLAGS}"
  1482. AS_IF([test "$use_hwloc" = "no"],
  1483. [have_valid_hwloc=no],
  1484. [AS_IF([test "$use_hwloc_from_system" = "yes"],
  1485. [PKG_CHECK_MODULES([HWLOC],[hwloc], [
  1486. have_valid_hwloc=yes
  1487. have_pkgconfig_hwloc=yes], [
  1488. have_valid_hwloc=no
  1489. have_pkgconfig_hwloc=no])
  1490. ],
  1491. #else
  1492. [have_pkgconfig_hwloc=no
  1493. CPPFLAGS="${SAVED_CPPFLAGS} -I$hwloc_dir/include"
  1494. AC_CHECK_HEADER([hwloc.h],[have_valid_hwloc=yes],[have_valid_hwloc=no])
  1495. LDFLAGS="${SAVED_LDFLAGS} -L$hwloc_dir/lib"
  1496. AC_HAVE_LIBRARY([hwloc],[have_valid_hwloc=yes],[have_valid_hwloc=no])
  1497. ])
  1498. ])
  1499. # in case hwloc was explicitely required, but is not available, this is an error
  1500. AS_IF([test "$use_hwloc" = "yes" -a "$have_valid_hwloc" = "no"],
  1501. [AC_MSG_ERROR([cannot find hwloc])]
  1502. )
  1503. # in case hwloc is not available but was not explicitely disabled, this is an error
  1504. AS_IF([test "$have_valid_hwloc" = "no" -a "$use_hwloc" != "no"],
  1505. [AC_MSG_ERROR([hwloc was not found on your system. If the target machine is hyperthreaded the performance may be impacted a lot. It is strongly recommended to install hwloc. However, if you really want to use StarPU without enabling hwloc, please restart configure by specifying the option '--without-hwloc'.])]
  1506. )
  1507. AS_IF([test "$have_valid_hwloc" = "yes"],
  1508. [AC_DEFINE([STARPU_HAVE_HWLOC], [1], [Define to 1 if you have the hwloc library.])
  1509. HWLOC_REQUIRES=hwloc
  1510. AC_SUBST([STARPU_HAVE_HWLOC], [1])
  1511. AS_IF([test "$have_pkgconfig_hwloc" = "no"],
  1512. [HWLOC_CFLAGS="-I$hwloc_dir/include"
  1513. HWLOC_LIBS="-L$hwloc_dir/lib -lhwloc"]
  1514. )
  1515. ])
  1516. LDFLAGS="${SAVED_LDFLAGS}"
  1517. CPPFLAGS="${SAVED_CPPFLAGS}"
  1518. AC_MSG_CHECKING(whether hwloc should be used)
  1519. AC_MSG_RESULT($have_valid_hwloc)
  1520. AC_SUBST(HWLOC_REQUIRES)
  1521. # is the header file f77.h available ?
  1522. AC_CHECK_HEADER([f77.h], [have_f77_h=yes], [have_f77_h=no])
  1523. AC_SUBST(STARPU_HAVE_F77_H, $have_f77_h)
  1524. AM_CONDITIONAL(STARPU_HAVE_F77_H, test x$have_f77_h = xyes)
  1525. if test x$have_f77_h = xyes; then
  1526. AC_DEFINE([STARPU_HAVE_F77_H], [1], [Define to 1 if you have the <f77.h> header file.])
  1527. fi
  1528. # Check if icc is available
  1529. AC_CHECK_PROGS([ICC], [icc])
  1530. # If cuda and icc are both available, check they are compatible
  1531. if test "$enable_cuda" = "yes" -a "$ICC" != ""; then
  1532. AC_MSG_CHECKING(whether CUDA and ICC are compatible)
  1533. OLD_CC="$CC"
  1534. CC="$ICC"
  1535. OLD_CFLAGS="$CFLAGS"
  1536. CFLAGS="-I$PWD/include -I$srcdir/include"
  1537. AC_COMPILE_IFELSE(
  1538. [AC_LANG_PROGRAM(
  1539. [[#include <cuda.h>
  1540. #include <starpu.h>]],
  1541. [[]]
  1542. )],
  1543. AC_MSG_RESULT(yes),
  1544. [ICC=""
  1545. AC_MSG_RESULT(no)]
  1546. )
  1547. CC="$OLD_CC"
  1548. CFLAGS="$OLD_CFLAGS"
  1549. fi
  1550. # Disable ICC on windows
  1551. if test "x$ICC" != "x" -a "$starpu_windows" = "yes" ; then
  1552. ICC=""
  1553. fi
  1554. if test "x$ICC" != "x"; then
  1555. AC_DEFINE(STARPU_HAVE_ICC, [], [Define this if icc is available])
  1556. fi
  1557. AM_CONDITIONAL([STARPU_HAVE_ICC], [test "x$ICC" != "x"])
  1558. # Do not generate manpages for the tools if we do not have help2man
  1559. AC_CHECK_PROGS([HELP2MAN], [help2man])
  1560. # Disable on windows
  1561. if test "$starpu_windows" = "yes" ; then
  1562. HELP2MAN=""
  1563. fi
  1564. AM_CONDITIONAL([STARPU_HAVE_HELP2MAN], [test "x$HELP2MAN" != "x"])
  1565. AC_CHECK_MEMBER([struct cudaDeviceProp.pciDomainID],
  1566. AC_DEFINE([STARPU_HAVE_DOMAINID],[1],[Define to 1 if CUDA device properties include DomainID]),
  1567. , [[#include <cuda_runtime_api.h>]])
  1568. AC_CHECK_MEMBER([struct cudaDeviceProp.pciBusID],
  1569. AC_DEFINE([STARPU_HAVE_BUSID],[1],[Define to 1 if CUDA device properties include BusID]),
  1570. , [[#include <cuda_runtime_api.h>]])
  1571. dnl Set this condition when Automake 1.11 or later is being used.
  1572. dnl Automake 1.11 introduced `silent-rules', hence the check.
  1573. m4_ifdef([AM_SILENT_RULES],
  1574. AM_CONDITIONAL([STARPU_HAVE_AM111], [true]),
  1575. AM_CONDITIONAL([STARPU_HAVE_AM111], [false]))
  1576. ##########################################
  1577. # Documentation #
  1578. ##########################################
  1579. AC_ARG_ENABLE(build-doc, [AS_HELP_STRING([--disable-build-doc],
  1580. [disable building of documentation])],
  1581. enable_build_doc=$enableval, enable_build_doc=yes)
  1582. AM_CONDITIONAL(BUILD_DOC, [test x$enable_build_doc != xno])
  1583. ###############################################################################
  1584. # #
  1585. # Final settings #
  1586. # #
  1587. ###############################################################################
  1588. # these are the flags needed for static linking
  1589. LIBSTARPU_LDFLAGS="$STARPU_GLPK_LDFLAGS"
  1590. AC_SUBST([LIBSTARPU_LDFLAGS])
  1591. LIBSTARPU_LINK=libstarpu-$STARPU_EFFECTIVE_VERSION.la
  1592. if test x$enable_perf_debug = xyes; then
  1593. LIBSTARPU_LINK=".libs/libstarpu-$STARPU_EFFECTIVE_VERSION.a $LIBSTARPU_LDFLAGS $HWLOC_LIBS $SIMGRID_LIBS $STARPU_CUDA_LDFLAGS $STARPU_OPENCL_LDFLAGS"
  1594. fi
  1595. AC_SUBST([LIBSTARPU_LINK])
  1596. # File configuration
  1597. AC_CONFIG_COMMANDS([executable-scripts], [
  1598. chmod +x tests/regression/regression.sh
  1599. chmod +x gcc-plugin/tests/run-test
  1600. chmod +x tools/starpu_workers_activity
  1601. ])
  1602. # Create links to ICD files in build/socl/vendors directory. SOCL will use this
  1603. # directory as the OCL_ICD_VENDORS directory
  1604. if test -d /etc/OpenCL/vendors; then
  1605. for icd in /etc/OpenCL/vendors/*.icd ; do
  1606. if test "$(basename $icd)" != "socl.icd" ; then
  1607. new_icd=$(basename $icd)
  1608. AC_CONFIG_LINKS([socl/vendors/$new_icd:$icd])
  1609. fi
  1610. done
  1611. fi
  1612. AC_CONFIG_FILES(tests/regression/regression.sh tests/regression/profiles tests/regression/profiles.build.only)
  1613. AC_CONFIG_HEADER(src/common/config.h include/starpu_config.h gcc-plugin/include/starpu-gcc/config.h starpu-top/config.h)
  1614. AC_OUTPUT([
  1615. Makefile
  1616. src/Makefile
  1617. tools/Makefile
  1618. tools/starpu_workers_activity
  1619. socl/Makefile
  1620. socl/src/Makefile
  1621. socl/examples/Makefile
  1622. socl/socl-1.0.pc
  1623. socl/vendors/socl.icd
  1624. libstarpu.pc
  1625. starpu-1.0.pc
  1626. mpi/libstarpumpi.pc
  1627. mpi/starpumpi-1.0.pc
  1628. starpufft/Makefile
  1629. starpufft/libstarpufft.pc
  1630. starpufft/starpufft-1.0.pc
  1631. examples/Makefile
  1632. examples/stencil/Makefile
  1633. tests/Makefile
  1634. doc/Makefile
  1635. mpi/Makefile
  1636. mpi/src/Makefile
  1637. mpi/tests/Makefile
  1638. mpi/examples/Makefile
  1639. starpu-top/StarPU-Top.pro
  1640. starpu-top/StarPU-Top-qwt-embed.pri
  1641. starpu-top/StarPU-Top-qwt-system.pri
  1642. gcc-plugin/Makefile
  1643. gcc-plugin/src/Makefile
  1644. gcc-plugin/tests/Makefile
  1645. gcc-plugin/tests/run-test
  1646. gcc-plugin/examples/Makefile
  1647. sched_ctx_hypervisor/Makefile
  1648. sched_ctx_hypervisor/src/Makefile
  1649. sched_ctx_hypervisor/examples/Makefile
  1650. ])
  1651. AC_MSG_NOTICE([
  1652. CPUs enabled: $enable_cpu
  1653. CUDA enabled: $enable_cuda
  1654. OpenCL enabled: $enable_opencl
  1655. Compile-time limits
  1656. (change these with --enable-maxcpus, --enable-maxcudadev,
  1657. --enable-maxopencldev, --enable-maxbuffers)
  1658. Maximum number of CPUs: $maxcpus
  1659. Maximum number of CUDA devices: $nmaxcudadev
  1660. Maximum number of OpenCL devices: $nmaxopencldev
  1661. Maximum number of memory nodes: $maxnodes
  1662. Maximum number of task buffers: $nmaxbuffers
  1663. GPU-GPU transfers: $have_cuda_memcpy_peer
  1664. Allocation cache: $enable_allocation_cache
  1665. Magma enabled: $have_magma
  1666. BLAS library: $blas_lib
  1667. hwloc: $have_valid_hwloc
  1668. FxT trace enabled: $use_fxt
  1669. StarPU-Top: $build_starpu_top
  1670. Documentation: $enable_build_doc
  1671. Examples: $enable_build_examples
  1672. StarPU Extensions:
  1673. MPI enabled: $use_mpi
  1674. MPI test suite: $running_mpi_check
  1675. FFT Support: $fft_support
  1676. GCC plug-in: $build_gcc_plugin
  1677. GCC plug-in test suite (requires GNU Guile): $run_gcc_plugin_test_suite
  1678. SOCL enabled: $build_socl
  1679. SOCL test suite: $run_socl_check
  1680. Scheduler Hypervisor: $build_sched_ctx_hypervisor
  1681. simgrid enabled: $enable_simgrid
  1682. ayudame enabled: $ac_cv_header_Ayudame_h
  1683. ])
  1684. if test "$build_socl" = "yes" -a "$run_socl_check" = "no" ; then
  1685. AC_MSG_NOTICE([
  1686. WARNING: SOCL test suite will not be run as the environment variable SOCL_OCL_LIB_OPENCL is not defined.
  1687. To run the tests, you need to install the OCL implementation of ICD
  1688. (https://forge.imag.fr/projects/ocl-icd/ or Debian package ocl-icd-libopencl1)
  1689. and set the variable SOCL_OCL_LIB_OPENCL to the location of the libOpenCL.so.])
  1690. fi
  1691. if test x"$have_valid_hwloc" = xno -a "$enable_simgrid" = "no"
  1692. then
  1693. AC_MSG_NOTICE([
  1694. WARNING: hwloc was not enabled. If the target machine is hyperthreaded the
  1695. performance may be impacted a lot. It is strongly recommended to install
  1696. hwloc])
  1697. fi